XML文件输入

Question

我正在尝试将xml文档转换为另一个文档以获取逗号限制字符串。但是，当我转换时，我会看到很多空格。

我不确定导致此问题的原因以及如何解决此问题 -

XML文件输入

    <File>
<row>
    <wid>WID0001</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E001</eid>
    <amt>5000</amt>
</row>


<row>
    <wid>WID0003</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E005</eid>
    <amt>3000</amt>
</row>

<row>
    <wid>WID0010</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E010</eid>
    <amt>7000</amt>
</row>


<row>
    <wid>WID0007</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E010</eid>
    <amt>0000</amt>
</row>

<row>
    <wid>WID0050</wid>
    <xtn>Leave Record</xtn>
    <status>In Process</status>
    <eid>E025</eid>
    <amt>750000</amt>
</row>

</File>

和XSLT -

<?xml version='1.0'?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:this="http://abogusurl.com">

    <xsl:output indent="yes" method="xml" />

        <xsl:template match="/File">
            <widlist>
                <xsl:apply-templates />
            </widlist>
        </xsl:template>

       <xsl:template match="row">
            <xsl:value-of select="wid" /> 
            <xsl:value-of select="','" />
    </xsl:template>

</xsl:stylesheet>

输出

<?xml version="1.0"?>
<widlist x xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:this="http://abogusurl.com">
WID0001,


WID0003,

WID0010,


WID0007,

WID0050,

</widlist>

如何消除空格？

Answer 1

您的XML在text()元素之间有row个节点。 built-in template rules在输出中保留它们。

您可以通过添加与仅空白文本节点匹配的空模板来禁止这些text()节点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:apply-templates/>
        </widlist>
    </xsl:template>

    <xsl:template match="row">
        <xsl:value-of select="wid"/>
        <xsl:value-of select="','"/>
    </xsl:template>

    <!--suppress whitespace-only text nodes-->
    <xsl:template match="text()[not(normalize-space())]"/>

</xsl:stylesheet>

您还可以使用空模板匹配File/text()：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:apply-templates/>
        </widlist>
    </xsl:template>

    <xsl:template match="row">
        <xsl:value-of select="wid"/>
        <xsl:value-of select="','"/>
    </xsl:template>

    <!--suppress (whitespace) text nodes that are children of File-->
    <xsl:template match="File/text()"/>

</xsl:stylesheet>

或者您可以通过仅将模板应用于文件模板中的File/text()元素来排除这些row节点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:apply-templates select="row"/>
        </widlist>
    </xsl:template>

    <xsl:template match="row">
        <xsl:value-of select="wid"/>
        <xsl:value-of select="','"/>
    </xsl:template>

</xsl:stylesheet>

所有这些解决方案都删除了额外的空格和换行符，并产生以下输出：

<widlist>WID0001,WID0003,WID0010,WID0007,WID0050,</widlist>

此实现目前在widlist中生成一个尾随逗号。

您可以通过更改行模板来解决此问题：

<xsl:template match="row">
    <xsl:value-of select="wid"/>
    <xsl:if test="position() != last()">
        <xsl:text>,</xsl:text>
    </xsl:if>
</xsl:template>

如果您正在使用XSLT 2.0并希望生成以逗号分隔的列表，则可以将样式表缩短为：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output indent="yes" method="xml"/>

    <xsl:template match="/File">
        <widlist>
            <xsl:value-of select="row/wid" separator=","/>
        </widlist>
    </xsl:template>

</xsl:stylesheet>

Answer 2

所以我认为添加<xsl:strip-space elements="*"/>会做你想做的事。

输出空间

XML文件输入

输出

2 个答案: