Question

在Common Lisp中，有(do *vars* *test* *body*)的顺序形式;就像让的顺序并行let*一样，它一次只能通过*vars*一个，这样你就可以像这样引用以前定义的变量：

(do* ((a '(1 2 3) (cdr a))
      (b (mapcar (lambda (x) (1+ x)) a) (cdr b)))
     ((= 1 1) (list 'a a 'b b)))
; (a (1 2 3) b (2 3 4))

在Scheme，AFAIK中，没有相关函数或宏。有do，但没有do*。我一直在努力为鸡计划编写do*的实施，但到目前为止，我正在努力取得任何进展......我想，我无法说出来。我对Chicken Scheme很熟悉，但我总是发现方案宏令人困惑。

这是我到目前为止所得到的：

(##sys#extend-macro-environment
 'do*
 '()
 (##sys#er-transformer
  (lambda (form r c)
(##sys#check-syntax 'do* form '(_ #((symbol _ . #(_)) 0) . #(_ 1)))
(let* ((bindings (cadr form))
       (test (caddr form))
       (body (cdddr form))
       (do*var (r 'doloop)))
  `(let*
       ,do*var
     ,(##sys#map (lambda (b) (list (car b) (car (cdr b)))) bindings)
     (##core#if ,(car test)
        ,(let ((tbody (cdr test)))
           (if (eq? tbody '())
               '(##core#undefined)
               `(##core#begin ,@tbody) ) )
        (##core#begin
         ,(if (eq? body '())
              '(##core#undefined)
              `(##core#let () ,@body) )
         (##core#app
          ,do*var ,@(##sys#map (lambda (b)
                     (if (eq? (cdr (cdr b)) '())
                         (car b)
                         (car (cdr (cdr b))) ) )
                       bindings) ) ) ) ) ) ) ) )

但是我继续得到像doloop这样的错误而不是列表 - 目前，我正在

Error: during expansion of (do* ...) - in `do*' - symbol expected: (do* ((a (quote (1 2 3)) (cdr a)) (b (map (lambda (x) (+ 1 x)) a) (cdr b)) ((= 1 1) (list (quote a) a (quote b) b))))

    Call history:

    <syntax>          (do* ((a (quote (1 2 3)) (cdr a)) (b (map           (lambda (x) (+ 1 x)) a) (cdr b)) ((= 1 1) (list (quote a) a...
    <eval>    (##sys#check-syntax (quote do*) form (quote (_ #((symbol _ . #(_)) 0) . #(_ 1))))     <--

以下是来自HyerSpec的Common Lisp中的粗略do*：

  (block nil        
   (let ((var1 init1)
     (var2 init2)
     ...
     (varn initn))
     declarations
     (loop (when end-test (return (progn . result)))
       (tagbody . tagbody)
       (psetq var1 step1
          var2 step2
          ...
          varn stepn))))

do *类似，只是让*和setq分别替换let和psetq。

这是do*扩展到CL：

的内容

(expand-form '(do* ((a '(1 2 3) (cdr a))
        (b (mapcar (lambda (x) (1+ x)) a) (cdr b)))
           ((= 1 1) (list 'a a 'b b))))
(block nil
   (let* ((a '(1 2 3)) (b (mapcar #'(lambda (x) (declare (system::source ((x) (1+ x)))) (1+ x)) a)))
     (tagbody #:loop-5382 (if (= 1 1) (go #:end-5383)) (setq a (cdr a) b (cdr b)) (go #:loop-5382) #:end-5383 (return-from nil (list 'a a 'b b))))) ;
;t

Answer 1

请不要使用## - 前缀标识符。那些不受支持且不是官方API的一部分！

其次，不要试图搞乱低级宏，只需使用语法规则，这更简单，更不容易出错并且标准化。无论何时你不需要打破卫生，都应该使用它。

以下是do *的示例，因为如果我理解正确的话，它会起作用：

(define-syntax do*
  (syntax-rules ()
    ((_ ((?var0 ?init0 ?inc0) ...)
         (?test ?result)
         ?body ...)
     (let* ((?var0 ?init0) ...)
       (let lp ()
         (cond (?test ?result)
               (else ?body ...
                     (set! ?var0 ?inc0) ...
                     (lp))))))))

表示为隐式重命名宏：

(define-syntax do*
  (ir-macro-transformer
   (lambda (e i c)
     (let* ((vars (cadr e))
            (test&result (caddr e))
            (test (car test&result))
            (result (cadr test&result))
            (body-exprs (cdddr e)))
       `(let* (,@(map (lambda (v) (list (car v) (cadr v))) vars))
          (let lp ()
            (cond (,test ,result)
                  (else ,@body-exprs
                        ,@(map (lambda (v) `(set! ,(car v) ,(caddr v))) vars)
                        (lp)))))))))

我希望你同意这种方式更加冗长。

方案的顺序Do（do *）

1 个答案: