Question

options orientation=portrait;
GOPTIONS device=ACTXIMG;
options nocenter nodate nonumber;

ods graphics / noborder width= 1200 height=360 scale;
ods pdf startpage=never file="\\...\aa.pdf";

title justify=center "t1";
proc sgplot 
... 
run;

title justify=center "t2";
proc sgplot 
... 
run;

ods pdf close;

我不明白为什么当我在同一页面中放置两个图形时，pdf输出中缺少第二个标题。

如果我在两个页面中放置两个图形，则会出现第二个标题。但我确实需要它们在同一页面。

如果可以在两个图形之间留下一些空白行，那会好得多。

理想输出：

title1 
graph1

title2
graph2

我做了什么：

title1 
graph1
graph2

Answer 1

建议在您的ODS声明中添加GTITLE选项。这应该告诉SAS将标题放在图形图像中，而不是页面标题中。我认为GTITLE已添加到v9.3中的ODS PDF中。

ods pdf file="d:\junk\want.pdf" startpage=never gtitle;

title1 "Some Title AAA";
proc sgplot data=sashelp.class;
  scatter x=height y=weight;
run;
title1;

title1 "Some Title BBB";
proc sgplot data=sashelp.class;
  scatter x=height y=weight;
run;
title1;
ods pdf close;

Answer 2

Reeza在sas社区的某些时候遇到了同样的问题。 Cynthia（SAS）解释说标题会出现在页面顶部。由于您通过删除分页符强制它使用相同的内容，因此不会显示第二个标题。解决它的一种方法是使用ODS文本。

请参阅下面的代码，它使用两个与您的代码相比较的新语句。第一行设置要在第二行中使用的转义字符，用于设置要使用的文本块而不是标题。

ods escapechar ='^';

ods pdf text =“^ S = {just = c}这是我的临时标题”;

options orientation=portrait;
GOPTIONS device=ACTXIMG;
ods escapechar='^';
options nocenter nodate nonumber;
ods graphics / noborder width= 1200 height=360 scale;
ods pdf startpage=never file="/home/healthcarep/work/floss/aa.pdf";
title justify=center "t1";

proc sgplot data=sashelp.class;
    scatter x=height y=weight / group=sex;
run;

title justify=center "t2";
ods pdf text="^S={just=c} This is my interim title";

proc sgplot data=sashelp.class;
    scatter x=height y=weight / group=sex;
run;

ods pdf close;

这是一种解决方法，但它可能会满足您的需求。

此致瓦西里

ods pdf输出中缺少图表标题

2 个答案: