Question

我在elixir中试验Macros。因此，即将展示的代码当然应该用简单的功能完成，但是......我正在尝试！

我想定义2个宏（A和B）并使A使用B来试验宏扩展。当我使用A时，我收到编译错误，指出函数 B 未定义。

以下是代码：

defmodule MyMacros do
  defmacro print_expr(expr) do
    quote do
      IO.puts(unquote(expr))
    end
  end

  defmacro print_hashes_around(expr) do
    quote do
      IO.puts "###"
      print_expr(unquote(expr))
      IO.puts "###"
    end
  end
end

defmodule MyModule do
  require MyMacros

  def my_print(expr) do
    MyMacros.print_hashes_around(expr)
  end
end

MyModule.my_print("hello world")

这是编译错误：

macro_test.exs:17: warning: redefining module MyModule
** (CompileError) macro_test.exs:21: function print_expr/1 undefined
(stdlib) lists.erl:1336: :lists.foreach/2
macro_test.exs:17: (file)
(elixir) lib/code.ex:307: Code.require_file/2

我（错误）理解事物的方式：

通过要求MyMacros，模块MyModule应该知道两个宏的存在。因此我应该可以使用任何宏。
当在MyModule中展开print_hashes_around时，编译器应该发现print_expr也是一个宏。因此，应该进行另一次扩张。
似乎发生的事情是第二次扩张不会发生。因此，编译器会查找不存在的函数定义。

我是对的吗？

正如松弛所建议的那样，print_expr前缀为MyMacros.可以修复它。我仍然不明白为什么。 MyModule需要MyMacros，因此两个宏都应该是已知且可扩展的...当我查看unless的定义时，它会使用if，而不是Kernel.if。

Answer 1

通过要求MyMacros，模块MyModule应该知道两个宏的存在。因此我应该可以使用任何宏。

误解就在这里。 :) require只使模块可用于编译器，它不会导入模块功能。如果您使用了import MyModule，那么它就会起作用。

但是，最好通过在模块名称前添加前缀来解决问题，因为这样您就可以使用代码明确地使用您的宏（使用require）或导入它们。

另一种选择是避免多次宏调用：

defmodule MyMacros do
  defmacro print_expr(expr) do
    quoted_print_expr(expr)
  end

  defmacro print_hashes_around(expr) do
    quote do
      IO.puts "###"
      unquote(quoted_print_expr(expr))
      IO.puts "###"
    end
  end

  defp quoted_print_expr(expr) do
    quote do
      IO.puts(unquote(expr))
    end
  end
end

灵药中的宏扩展：如何使用另一个宏定义2个宏？

1 个答案: