Question

我正在使用Delphi XE8。

我只是看REST.Json ObjectToJsonString()和JsonToObject()来电。

主要尝试做这样的事情：

How to convert an object to JSON and back with a single line of code

我注意到，当他们以F字符开头时，我只能让变量工作。我找不到任何关于此的文件。这是预期的行为吗？我应该在开始时使用F命名我的类中的所有变量吗？如果是，有人可以解释原因吗？

我创建了一个类TTestJSON并定义了两个成员变量并将它们设置为'WORKS'和'FAILS'。

然后我从对象中创建了一个JSON字符串值：

{
  "varThatWorksBeacuseItStartsWithF":"WORKS",
  "sVarThatFailsBecauseItStartsWithS":"FAILS"
}

从JSON字符串返回到object时，只有正确重置fVarThatWorksBeacuseItStartsWithF变量。在下面的代码中test := TJson.JsonToObject<TTestJSON>(JsonStr);使用上述JSON，请注意sVarThatFailsBecauseItStartsWithS为""而非"FAILS"。

procedure TForm3.btn1Click(Sender: TObject);
var
  test : TTestJSON;
  JsonStr : String;
begin
  m1.Clear;
  test := TTestJSON.Create;
  try
    test.fVarThatWorksBeacuseItStartsWithF := 'WORKS';
    test.sVarThatFailsBecauseItStartsWithS := 'FAILS';
    JsonStr := TJson.ObjectToJsonString( test );
  finally
    test.Free;
  end;
  m1.Lines.Add(  '** JSONStr Value START **' + #13#10 + JsonStr + '** JSONStr Value END **' + #13#10 );

  test := TJson.JsonToObject<TTestJSON>(JsonStr);
  try
    m1.Lines.Add('** Obj loaded from JSON String Start **' + #13#10 + TJson.ObjectToJsonString( test ) + #13#10 + '** Obj loaded from JSON String End **');
  finally
    test.Free;
  end;
end;

从结果中，以f开头的var将f从JSON字符串中删除，而以s开头的那个仍然存在于其中。我原以为第二个结果会是这样的：

{
  "varThatWorksBeacuseItStartsWithF":"WORKS",
  "sVarThatFailsBecauseItStartsWithS":"FAILS"
}

以下是重现的完整代码 - 在vcl表单上只有一个按钮和一个备忘录 - 也使用REST.Json：

unit Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, rest.Json;

type
  TTestJSON = class
    fVarThatWorksBeacuseItStartsWithF : String;
    sVarThatFailsBecauseItStartsWithS : String;
  end;

  TForm3 = class(TForm)
    btn1: TButton;
    m1: TMemo;
    procedure btn1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  Form3: TForm3;

implementation

{$R *.dfm}

procedure TForm3.btn1Click(Sender: TObject);
var
  test : TTestJSON;
  JsonStr : String;
begin
  m1.Clear;
  test := TTestJSON.Create;
  try
    test.fVarThatWorksBeacuseItStartsWithF := 'WORKS';
    test.sVarThatFailsBecauseItStartsWithS := 'FAILS';
    JsonStr := TJson.ObjectToJsonString( test );
  finally
    test.Free;
  end;
  m1.Lines.Add(  '** JSONStr Value START **' + #13#10 + JsonStr + '** JSONStr Value END **' + #13#10 );

  test := TJson.JsonToObject<TTestJSON>(JsonStr);
  try
    m1.Lines.Add('** Obj loaded from JSON String Start **' + #13#10 + TJson.ObjectToJsonString( test ) + #13#10 + '** Obj loaded from JSON String End **');
  finally
    test.Free;
  end;
end;

end.

Answer 1

Delphi中的JSON序列化基于字段，而不是属性。但是大多数Delphi类都有友好属性和F前缀字段。同时，Emb似乎试图避免生成的JSON中的F前缀名称。他们先切断了F＆＃34; F＆＃34;从序列化字段时的名称，并在从JSON读取时将其添加回（以查找正确的字段）。似乎在Delphi中使用JSON序列化的唯一（安全）方法是保留所有字段名称前缀＆＃34; F＆＃34; （对于要序列化的字段）：

TTestJSON = class
protected
  FName: String;
public
  property Name: String read FName write FName;
end;

UPDATE2：正如David所提到的，我们可以使用属性，然后我们可以更好地控制：

uses
  REST.Json.Types, // without this unit we get warning: W1025 Unsupported language feature: 'custom attribute'
  REST.Json;

type
  // All fields of records are serialized, no control here.
  TRec = record
    RecStr: String;
  end;

  // By default all fields of class are serialized, but only F-prefixed serialized correctly.
  // We can use JSONMarshalled attribute to enable/disable serialization.
  // We can use JSonName attribute to serialize field with specific name in JSON.
  TTestJSON = class
    [JSONMarshalled(True)] [JSonName('RecField')]
    R: TRec;
  end;

procedure TForm28.FormCreate(Sender: TObject);
var
  Test: TTestJSON;
  JsonStr: string;
begin
  Test := TTestJSON.Create;
  try
    Test.R.RecStr := 'Some str';
    JsonStr := TJson.ObjectToJsonString( Test );
  finally
    FreeAndNil(Test);
  end;

  // JsonStr: {"RecField":["Some str"]}

  Test := TJson.JsonToObject<TTestJSON>(JsonStr);
  FreeAndNil(Test);
end;

Answer 2

此库序列化字段。由于通常的做法是在字段前加上字母F，因此设计人员希望从JSON中使用的名称中删除该字母。所以他们决定将默认行为剥离出名字以F开头的字段中的第一个字母。坦率地说，这对我来说似乎很奇怪。

可以使用属性自定义此行为。例如：

[JSONMarshalled(False)]
FFoo: Integer; 

[JSONMarshalled(True)]
[JSONName('Blah')]
Bar: Integer;

据我所知，这些都没有被正确记录。

Delphi Rest.JSON JsonToObject仅适用于f变量

2 个答案: