来自F＃的Haskell RPN计算器

Question

我是Haskell的新手，有人可以建议我如何将F＃中的以下程序重写为Haskell，以便它尽可能地相似。

不知道如何在Haskell中定义堆栈数据类型。

由于

let calc input (stck:Stack<double>) =
    match input with
        | "*" -> stck.Push(stck.Pop() * stck.Pop())
        | "+" -> stck.Push(stck.Pop() + stck.Pop())
        | "-" -> stck.Push(stck.Pop() - stck.Pop())
        | "/" -> stck.Push(stck.Pop() / stck.Pop())
        | _ -> stck.Push(System.Convert.ToDouble(input))

let evalu (inputStr:string) =
    let stk = Stack<double>()

    let elem = inputStr.Split([|' '|])

    Array.iter (fun ent -> calc ent stk) elem
    stk.Pop()

//Call
Console.WriteLine(evalu("3 5 +"))

希望有类似的内容：

calc input stck
    | input == '*' = stck.push(stck.pop * stck.pop)
    | input == '+' = stck.push(stck.pop + stck.pop)
    | input == '-' = stck.push(stck.pop - stck.pop)
    | input == '/' = stck.push(stck.pop / stck.pop)
    | otherwise   = stck.push(input)

main = calc "3 5 +" [] //Somehow do folding

Answer 1

这是一个非常基本的翻译：

module Main where

type Stack = [Double]

push :: Stack -> Double -> [Double]
push s v = v:s

pop :: Stack -> (Double, Stack)
pop []    = error "empty stack"
pop (v:s) = (v,s)

calc :: Stack -> String -> Stack
calc stck "+" = let (v1,stck') = pop stck
                    (v2,stck'') = pop stck'
                in push stck'' $ v1+v2
calc stck n = push stck $ read n

eval :: String -> Double
eval = head . foldl calc [] . words

main :: IO ()
main = print $ eval "3 5 +"

因为.net的Stack并不纯粹我选择使用一个简单的列表作为替代，这当然意味着您必须通过计算来线程 state （堆栈） （这是let (v1,stck)...部分的工作）

我认为对于初学者来说这是最简单的一个 - 如果你提高了一点，你可能会回来并使用状态monad重新实现这一点（事实上我用伪装的伪装完全使用它）使它更多一点可读/美丽

当然，您必须为您的运营商添加其他案例

备注

这会导致输入格式错误（与您的版本一样） - 如果您愿意，可以在Maybe（pop，calc和eval）中加注。

让它更好一点

如果您自己实施这些案例，您会发现let ... pop ... push内容正在重复 - 所以让我们 DRY ：

apply :: (Double -> Double -> Double) -> Stack -> Stack
apply op stack =
  let (a,stack')  = pop stack
      (b,stack'') = pop stack'
  in push stack'' (b `op` a)

calc :: Stack -> String -> Stack
calc stack "+" = apply (+) stack
calc stack "*" = apply (*) stack
calc stack "-" = apply (-) stack
calc stack "/" = apply (/) stack
calc stack n = push stack $ read n

另请注意，您必须撤消操作，因为弹出的顺序错误

如果您不介意flip：

calc :: String -> Stack -> Stack
calc "+" = apply (+)
calc "*" = apply (*)
calc "-" = apply (-)
calc "/" = apply (/)
calc n   = flip push $ read n

eval :: String -> Double
eval = head . foldl (flip calc) [] . words

这是一个例子：

λ> eval "3 5 + 2 - 3 /"
2.0

Answer 2

这个（非常受欢迎的）教程解决了这个问题：

http://learnyouahaskell.com/functionally-solving-problems#reverse-polish-notation-calculator