Question

Racket新手。我一直试图制作一个简单的矢量结构并定义常见的矢量函数（点积，范数......）。我知道数学/矩阵，但现在不想使用它。

一切都很顺利，直到我尝试创建一个＆＃34;减号函数＆＃34;减去矢量。加法函数工作正常，但减法会引发类型检查错误。这是代码：

#lang typed/racket

(struct: vect ([x : Real]
               [y : Real])
  #:transparent)

(: vect+ (-> vect * vect))
(define (vect+ . vs)
  (vect (apply + (map vect-x vs))
        (apply + (map vect-y vs))))

(: vect- (-> vect * vect))
(define (vect- . vs)
  (vect (apply - (map vect-x vs))
        (apply - (map vect-y vs))))

(vect+ (vect 1 2) (vect -3 1) (vect 0 4))

(vect- (vect 1 2) (vect -3 1) (vect 0 4))

vect +（向量加法）函数工作正常，但vect函数引发：

. Type Checker: Bad arguments to function in `apply':
Domains: Number Number *
Arguments: (Listof Real) *
 in: (apply - (map vect-x vs))
. Type Checker: Bad arguments to function in `apply':
Domains: Number Number *
Arguments: (Listof Real) *
 in: (apply - (map vect-y vs))
. Type Checker: Summary: 2 errors encountered in:
  (apply - (map vect-x vs))
  (apply - (map vect-y vs))

为什么＆＃34;减去＆＃34;拒绝实施＆＃34;加＆＃34;拿走它们，以下行可行吗？

    (apply - (list 1 2 3))
    ; -> -4

Answer 1

错误是因为apply期望它的第一个参数是一个接受零或多个参数的函数，但是-需要一个或多个参数（注意+因为它接受零参数而起作用。）

> (:print-type apply)
(All (a b) (-> (-> a * b) (Listof a) b))
> (:print-type -)
; big output omitted, 
; but notice it includes (-> Number Number * Number),
; but not (-> Number * Number))
> (-)
. Type Checker: could not apply function;
 wrong number of arguments provided
  expected at least: 1
  given: 0 in: (-)
> (+)
- : Integer [more precisely: Zero]
0

为了解决这个问题，您可以cast apply接受一个或多个函数作为其第一个参数的函数：

(: vect- (-> vect vect * vect))
(define (vect- . vs)
  (define apply1+
    (cast apply (All (a b) (-> (-> a a * b) (Listof a) b))))
  (vect (apply1+ - (map vect-x vs))
        (apply1+ - (map vect-y vs))))

(vect- (vect 1 2) (vect -3 1) (vect 0 4)) ; (vect 4 -3)

请务必相应地更新vect-的类型。

OR，您可以定义一个接受零参数的替代减法函数：

(: new- (-> Real * Real))
(define (new- . args)
  (if (empty? args)
      0
      (apply - args)))

(: vect- (-> vect * vect))
(define (vect- . vs)
  (vect (apply new- (map vect-x vs))
        (apply new- (map vect-y vs))))

在这里，可以给vect-零参数。

Answer 2

（建立stchang的回答）如果您将vect-的定义更改为：

，则此方法有效

(: vect- (-> vect vect * vect))
(define (vect- v . vs)
  (vect (apply - (vect-x v) (map vect-x vs))
        (apply - (vect-y v) (map vect-y vs))))

这正是因为-没有采用零参数。因此，apply需要一些保证，至少会有一个论点。

Answer 3

我的猜测是减法的工作方式不同，因为：

    #lang racket
    (- 5)             ; -> -5
    (- 5 3)           ; -> 2

所以我定义了一个neg函数，它给出了向量的反面并定义了vect-的语法。很确定这是一种矫枉过正，但我不知道如何更简单地做到这一点。因此，将其添加到代码中可以：

(: neg (-> vect vect))
(define (neg v)
  (vect (- (vect-x v))
        (- (vect-y v))))

(define-syntax vect-
  (syntax-rules ()
    [(vect- v) (neg v)]
    [(vect- v1 v2 ...) (apply vect+ (list* v1 (map neg (list v2 ...))))]))

......但我非常确定有更好的方法。

定义＆＃34;减号功能＆＃34;对于类型/球拍

3 个答案: