Question

我在删除以下工作表中的重复单元格时遇到问题。 Col E是小时，col F是时间戳的分钟，我想组织。我想要做的是在一小时内删除包含重复分钟的所有行，这样我每5分钟就可以获得当前和功率的读数。问题是，有时你会在一分钟内获得5个甚至6个读数（因为读数是每9,10或11秒）。另一个问题是，我不能简单地删除所有重复的单元格一天，因为模式每小时重复一次，因此如果我只选择所有单元，那么只留下一小时的读数细胞

我在下面的代码中尝试通过双击第一个＆＃34; E＆＃34;在一小时内删除所有具有双分钟值的行。小区，小时首次出现。它的工作原理应该是第一个小时（0：00-0：55），但是对于后来的数字（小时），它会开始删除其他行。下一个合乎逻辑的步骤是删除一天的所有双重值。

整个事情并不需要用户友好或互动，我只想过滤掉5分钟的阅读时间，如果没有其他内容，请将它们粘贴到新的工作表上进行进一步分析。

这是工作表的printscreen，其中包含数据

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim clickedRow As Long
Dim clickedValue As Long
Dim currentValue As Long
Dim counter As Long

clickedRow = ActiveCell.Row
clickedValue = ActiveCell.Value

For i = clickedRow To (clickedRow + 100)
    currentValue = Range("E" & i).Value
    If (clickedValue = currentValue) Then
        counter = counter + 1
    Else
        Exit For
    End If
Next i

ActiveSheet.Range("A" & clickedRow, "Y" & counter).RemoveDuplicates Columns:=6, Header:=xlNo

End Sub

我试过的另一件事，虽然没有留下任何重复的细胞，但它并没有被证明是有效的：

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

Dim clickedRow As Long
Dim clickedValue As Long
Dim currentValue As Long
Dim zadnja As Long
Dim trenutna As Long

clickedRow = ActiveCell.Row
clickedValue = ActiveCell.Value

For i = clickedRow To (clickedRow + 100)

    currentValue = Range("E" & i).Value

    If (currentValue = clickedValue) Then

        zadnja = 5
        trenutna = Range("F" & i).Value

        If (trenutna = zadnja) Then
            Range("E" & i).EntireRow.Hidden = True
        Else
        End If

        zadnja = trenutna

    Else
        Exit For
    End If

Next i

End Sub

Answer 1

当您使用Range.RemoveDuplicates method时，您需要同时考虑小时和分钟。目前，您只是基于分钟的复制标准（例如，列（6））。

Option Explicit

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)

    On Error GoTo bm_Safe_Exit
    If Not Intersect(Target, Union(Columns(5), Columns(6))) Is Nothing Then
        Cancel = True
        Dim xlOriginalCalculation As Long, fr As Long, er As Long, tr As Long
        Application.EnableEvents = False
        xlOriginalCalculation = Application.Calculation
        Application.Calculation = xlCalculationManual

        tr = Target.Row
        fr = Application.Match(Cells(tr, 5).Value, Columns(5), 0)
        If Target.Column = 6 Then
            fr = fr + Application.Match(Cells(tr, 6).Value, Cells(fr, 6).Resize(1440, 1), 0) - 1
            er = fr + Application.CountIfs(Columns(5), Cells(tr, 5).Value, Columns(6), Cells(tr, 6).Value) - 1
        Else
            er = fr + Application.CountIfs(Columns(5), Cells(tr, 5).Value) - 1
        End If

        If fr <> er Then
            With Range("A" & fr & ":Y" & er)
                .RemoveDuplicates Columns:=Array(5, 6), Header:=xlNo
            End With
            With Range("A:Y")
                .Cells.Sort key1:=.Columns(5), order1:=xlAscending, _
                            key2:=.Columns(6), order2:=xlAscending, _
                            Orientation:=xlTopToBottom, Header:=xlYes
            End With
        End If
    End If

bm_Safe_Exit:
    Application.EnableEvents = True
    Application.Calculation = xlOriginalCalculation

End Sub

根据小时和分钟删除了重复项，这样第0小时55分钟就不会与第1小时55分钟混淆。

如果双击MINS列（列F），则根据分钟扣除数据。如果双击HRS列，则会扣除所有小时数据。

ActiveSheet不需要工作表代码表。

删除定期重复的重复单元格

1 个答案: