Question

我一直试图找到一种方法，只将某些列转换为excel中的行，以实现我的结果。

由于我需要输出为文本值，因此我无法使用数据透视表。这是附图，显示了我拥有的和我需要的东西。

非常感谢任何见解！

enter image description here

Answer 1

您没有指定excel-vba技术标记，但我发现这些是最佳解决方案，只要您允许某些参数是动态的;例如根据原始数据的大小和性质分配。

Sub collate()
    Dim rw As Long, rc As Long, rr As Long, r As Long, c As Long

    With Sheets("Sheet2")    '<-set this worksheet reference properly!
        rr = Application.Match("item id", .Columns(1), 0)
        rc = .Cells(rr, Columns.Count).End(xlToLeft).Column + 2
        .Cells(rr, rc + 1) = .Cells(rr + 1, 2).Value2

        For rw = rr + 1 To .Cells(Rows.Count, 1).End(xlUp).Row
            If IsError(Application.Match(.Cells(rw, 1).Value2, .Columns(rc), 0)) Then
                .Cells(Rows.Count, rc).End(xlUp).Offset(1, 0) = .Cells(rw, 1).Value2
            End If
            If IsError(Application.Match(.Cells(rw, 2).Value2, .Cells(rr, rc).Resize(1, 999), 0)) Then
                .Cells(rr, Columns.Count).End(xlToLeft).Offset(0, 1) = .Cells(rw, 2).Value2
            End If

            r = Application.Match(.Cells(rw, 1).Value2, .Columns(rc), 0)
            c = Application.Match(.Cells(rw, 2).Value2, .Rows(rr), 0)
            .Cells(r, c) = .Cells(rw, 3).Value
        Next rw

        With .Cells(rr, rc).CurrentRegion
            With .Resize(.Rows.Count - 1, .Columns.Count).Offset(1, 0)
                 .Cells.Sort Key1:=.Columns(1), Order1:=xlAscending, _
                            Orientation:=xlTopToBottom, Header:=xlNo
            End With
            With .Resize(.Rows.Count, .Columns.Count - 1).Offset(0, 1)
                 .Cells.Sort Key1:=.Rows(1), Order1:=xlAscending, _
                            Orientation:=xlLeftToRight, Header:=xlNo
            End With
        End With

    End With
End Sub

在大概重复数据运行后，我想出了这些结果。

Collate and Sort

请注意，我已使用无序3005条目专门更改了数据，以演示对结果数据执行的水平排序例程。

Answer 2

请根据您的示例考虑以下解决方案。

G3=IF(SUMIFS($C$4:$C$13,$A$4:$A$13,$F4,$B$4:$B$13,G$3)>0,SUMIFS($C$4:$C$13,$A$4:$A$13,$F4,$B$4:$B$13,G$3),"")

这假设“项目ID”和“扫描事件ID”的每个组合仅显示一次。这允许我们使用SUMIFS函数添加唯一的相关结果。请注意，excel会根据日期序列号添加它。

if是为了防止Excel显示返回0并被解析为实际日期的公式。

然后，您可以将公式拖到输出表的其余部分。的问候，

Excel转置 - 基于单元格值

2 个答案: