Question

我正在使用re-frame cljs框架，该框架使用reagent作为其视图库。我有一个nvd3图表组件，我想在订阅更新时更新。

不幸的是，在初次调用:component-did-mount后，图表永远不会自动更新。在初始渲染之后永远不会再调用:component-will-update。

我希望图表能够自动更新，因为订阅会通知它正在收听的数据的组件。

这是图形容器组件：

(defn weight-graph-container
  []
  (let [weight  (subscribe [:weight-change])
        bodyfat (subscribe [:bodyfat-change])
        weight-amount (reaction (get @weight :amount))
        weight-unit   (reaction (get @weight :unit))
        bf-percentage (reaction (get @bodyfat :percentage))
        lbm           (reaction (lib/lbm @weight-amount @bf-percentage))
        fat-mass      (reaction (- @weight-amount @lbm))]
    (reagent/create-class {:reagent-render weight-graph
                           :component-did-mount (draw-weight-graph @lbm @fat-mass "lb")
                           :display-name "weight-graph"
                           :component-did-update (draw-weight-graph @lbm @fat-mass "lb")})))

这是图表组件：

(defn draw-weight-graph [lbm fat-mass unit]
  (.addGraph js/nv (fn []
                     (let [chart (.. js/nv -models pieChart
                                     (x #(.-label %))
                                     (y #(.-value %))
                                     (showLabels true))]
                       (let [weight-data [{:label "LBM" :value lbm} {:label "Fat Mass" :value fat-mass}]]
                         (.. js/d3 (select "#weight-graph svg")
                                   (datum (clj->js weight-data))
                                   (call chart)))))))

最后，这是图表呈现的组件：

(defn weight-graph []
  [:section#weight-graph
   [:svg]])

我错过了什么？谢谢你的帮助。

Answer 1

以下代码解决了您的问题：

(defn draw-weight-graph
  [d]
  (let [[lbm fat-mass unit] (reagent/children d)]
    (.addGraph js/nv (fn []
                       (let [chart (.. js/nv -models pieChart
                                       (x #(.-label %))
                                       (y #(.-value %))
                                       (showLabels true))]
                         (let [weight-data [{:label "LBM" :value lbm} {:label "Fat Mass" :value fat-mass}]]
                           (.. js/d3 (select "#weight-graph svg")
                               (datum (clj->js weight-data))
                               (call chart))))))))

(def graph-component (reagent/create-class {:reagent-render weight-graph
                                            :component-did-mount draw-weight-graph
                                            :display-name "weight-graph"
                                            :component-did-update draw-weight-graph}))

(defn weight-graph-container
  []
  (let [weight  (subscribe [:weight-change])
        bodyfat (subscribe [:bodyfat-change])
        weight-amount (reaction (get @weight :amount))
        weight-unit   (reaction (get @weight :unit))
        bf-percentage (reaction (get @bodyfat :percentage))
        lbm           (reaction (lib/lbm @weight-amount @bf-percentage))
        fat-mass      (reaction (- @weight-amount @lbm))]
  (fn []
     [graph-component @lbm @fat-mass "lb"])))

重新框架：nvd3图形在其组件的订阅更新时没有响应

1 个答案: