Question

我正在使用身份验证构建Phoenix应用程序。在我的路由器中，我有类似的东西：

pipeline :browser do
    plug :accepts, ["html"]
    plug MyApp.Plugs.Authenticate
end

scope "/", MyApp do
    pipe_through :browser # Use the default browser stack

    get "/", HomeController, :show
    get "/login", SessionsController, :login
    get "/matches", MatchesController, :index
end

我想跳过/ login的Authenticate插件，我可以在路由器中执行此操作，还是必须在插件本身中执行此操作？

Plugs.Authenticate看起来像：

def call(conn, _) do
    case Authenticator.find_user(conn) do
        {:ok, user} ->
            assign(conn, :user, user)
        :error ->
            conn
                |> redirect(to: "/login")
                |> halt
    end
end

Answer 1

这样做的一种方法是定义一个单独的管道：

pipeline :browser do
    plug :accepts, ["html"]
end

pipeline :auth do
    plug MyApp.Plugs.Authenticate
end

scope "/", MyApp do
    pipe_through [:browser, :auth]

    get "/", HomeController, :show
    get "/matches", MatchesController, :index
end

scope "/", MyApp do
    pipe_through :browser

    get "/login", SessionsController, :login
end

这里有几点需要注意。

1）在需要验证的示例中，管道被链接。

2）只要实际路线不同，您可以多次使用相同的范围，这是因为上面的路线大致编译为：

defmodule MyRouter do
  def match(conn, :get,    ["/"])
  def match(conn, :get,    ["/matches"])
  def match(conn, :get,    ["/login"])
end

您可以在http://www.chrismccord.com/blog/2014/03/13/write-less-do-more-and-have-fun-with-elixir-macros/

详细了解Phoenix路由中的宏如何工作到幻灯片的末尾

如何跳过特定页面的插件

1 个答案: