Question

%include "init.inc"

[org 0x0]
[bits 16]

jmp 0x07C0:start_boot

start_boot:
    mov ax, cs
    mov ds, ax
    mov es, ax

load_setup:
    mov ax, SETUP_SEG
    mov es, ax
    xor bx, bx

    mov ah, 2           ; copy data to es:bx from disk.
    mov al, 1           ; read a sector.
    mov ch, 0           ; cylinder 0
    mov cl, 2           ; read data since sector 2.
    mov dh, 0           ; Head  = 0
    mov dl, 0           ; Drive = 0
    int 0x13            ; BIOS call.

    jc load_setup

    lea si, [msg_load_setup]
    call print

    jmp $

print:
print_beg:
    mov ax, 0xB800
    mov es, ax
    xor di, di

print_msg:
    mov al, byte [si]
    mov byte [es:di], al
    or al, al
    jz print_end
    inc di
    mov byte [es:di], BG_TEXT_COLOR
    inc di
    inc si
    jmp print_msg

print_end:
    ret

msg_load_setup db "Loading setup.bin was completed." , 0

times 510-($-$$) db 0
dw 0xAA55

我想将setup.bin加载到内存地址零。因此，我向es寄存器输入0值（SETUP_SEG = 0）。 bx也是。但它没有用。那么，我对这个问题有疑问。我的测试如下。

SETUP_SEG的值
0x0000：失败
0x0010：成功
0x0020：失败
0x0030：失败
0x0040：失败
0x0050：成功

我无法理解为什么会出现这种情况。所有测试均在VMware上进行。有没有人有想法？

Answer 1

我不确定这是不是您的问题，但是您尝试在Real Mode IVT（中断向量表）中加载setup.bin。 IVT包含每个中断的位置，所以我假设你的boatloader在将setup.bin加载到内存时会覆盖它们！中断可能是偷偷摸摸和棘手的，因为即使你没有调用它们，它们可以被调用。您覆盖的任何中断向量都可能在调用时导致未定义的行为，将导致一些问题。

我建议将SETUP_SEG设置为更高的数字，例如0x2000或0x3000，但是安全去的最低值是0x07E0。 Osdev Wiki和Wikipedia提供了有关常规内存和内存映射的一些有用信息。

我希望这有帮助！

读取扇区以解决零

1 个答案: