Question

我没有VBA经验。我知道有很多类似于这个问题的答案，但我无法调整任何代码以使其适合我。

我有一张表格中包含大量行的Excel工作表。
A列中有一些值（数字），B列中有一些注释（文本）。我想做这些注释（B列））作为对A栏中单元格的评论。

但这是条件：
A栏中的某些单元格已对其进行了评论，我不想用笔记替换它们。所以我需要一个代码，可以跳过这些特定的单元格，或者将它们的注释与注释合并。

Answer 1

在这里，我的解决方法是：

Public Sub addComment()

    Dim row As Integer
    Dim oldComment As String

    'Set start row
    row = 1

    With Sheets("sheetname")

        'Do until "A" cell is blank
        Do While .Range("A" & row) <> ""

            'If "B" cell is not blank
            If .Range("B" & row) <> "" Then

                'If "A" has no comment, set "" to oldComment
                If .Range("A" & row).Comment Is Nothing Then
                    oldComment = ""

                'Else comment is exist
                Else

                    'Store that comment to oldComment
                    oldComment = .Range("A" & row).Comment.Text & " "

                    'Delete comment from cell
                    .Range("A" & row).Comment.Delete

                End If

                'Insert comment for "A" with old if exist
                .Range("A" & row).addComment (oldComment & .Range("B" & row).Value)

            End If

            'Increase row
            row = row + 1

        Loop

    End With

End Sub

使用条件从相邻单元格值添加注释

1 个答案: