Question

我仍然是XSLT的初学者，但我手头有一项艰巨的任务。

我有一个需要转换的非xml文件。该文件的格式如下：

type1
type1line1
type1line2
type1line3
type2
type2line1
type2line2
type3
type3line1
type3line2

使用某些没有特定顺序的代码指定

类型（type1, type2, ...）。每种类型下面都有多个line。

所以，我需要转换这个文件，但问题是对于每个type我必须为每个基础行做一个不同的转换。

现在，我可以逐行读取字符串并确定新类型已经开始，但我不知道如何设置一个标志（指示类型）以在底层行中使用它。

这就是我现在所拥有的：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" version="2.0">  
  <xsl:param name="testString" as="xs:string">
  type1
  line1
  line2
  type1
  line1 
  </xsl:param>  
  <xsl:template match="/"> 
    <xsl:call-template name="main"> 
      <xsl:with-param name="testString" select="$testString"/> 
    </xsl:call-template> 
  </xsl:template>  

  <xsl:template name="main"> 
    <xsl:param name="testString"/>
    <xsl:variable name="iniFile" select="$testString"/>  
    <config> 
      <xsl:analyze-string select="$iniFile" regex="\n"> 
        <xsl:non-matching-substring> 
          <item> 
            <xsl:choose> 
              <xsl:when test="starts-with(., 'type1')">
   <!-- do a specific transformation-->     
              </xsl:when> 
              <xsl:when test="starts-with(., 'type2')">
   <!-- do another transformation-->      
              </xsl:when>
            </xsl:choose> 
          </item> 
        </xsl:non-matching-substring> 
      </xsl:analyze-string> 
    </config> 
  </xsl:template> 
</xsl:stylesheet>

关于如何解决问题的任何想法。

Answer 1

我认为XSLT 2.1允许你在原子值序列中使用像for-each-group这样强大的东西，比如字符串，但是对于XSLT 2.0，你只有节点序列才有这么强大的功能所以我在使用XSLT 2.0时的第一步我希望处理/分组的纯字符串数据是创建元素。因此，您可以对数据进行标记，将每个标记包装到某个元素中，然后使用for-each-group-starting-with来处理每个组，从某些模式开始，例如'^ type [0-9] + $'。一旦您确定了一个组，您就没有真正告诉我们您想要的数据，因此请将以下内容作为您可以适应的示例：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

  <xsl:output method="xml" indent="yes"/>

  <xsl:param name="input" as="xs:string">type1
type1line1
type1line2
type1line3
type2
type2line1
type2line2
type3
type3line1
type3line2</xsl:param>

   <xsl:template name="main">
     <xsl:variable name="lines" as="element(item)*">
       <xsl:for-each select="tokenize($input, '\n')">
         <item><xsl:value-of select="."/></item>
       </xsl:for-each>
     </xsl:variable>
     <xsl:for-each-group select="$lines" group-starting-with="item[matches(., '^type[0-9]+$')]">
       <xsl:choose>
         <xsl:when test=". = 'type1'">
           <xsl:apply-templates select="current-group() except ." mode="m1"/>
         </xsl:when>
         <xsl:when test=". = 'type2'">
           <xsl:apply-templates select="current-group() except ." mode="m2"/>
         </xsl:when>
         <xsl:when test=". = 'type3'">
           <xsl:apply-templates select="current-group() except ." mode="m3"/>
         </xsl:when>
       </xsl:choose>
     </xsl:for-each-group>
   </xsl:template>

   <xsl:template match="item" mode="m1">
     <foo>
       <xsl:value-of select="."/>
     </foo>
   </xsl:template>

   <xsl:template match="item" mode="m2">
     <bar>
       <xsl:value-of select="."/>
     </bar>
   </xsl:template>

   <xsl:template match="item" mode="m3">
     <baz>
       <xsl:value-of select="."/>
     </baz>
   </xsl:template>

</xsl:stylesheet>

当应用Saxon 9（命令行选项-it：main -xsl：sheet.xsl）时，结果是

<foo>type1line1</foo>
<foo>type1line2</foo>
<foo>type1line3</foo>
<bar>type2line1</bar>
<bar>type2line2</bar>
<baz>type3line1</baz>
<baz>type3line2</baz>

复杂的XSL转换

1 个答案: