Question

我有一个包含以下内容的XML文档：

<d1/>
<p1>...</p1>
<p2>...</p2>
<d2/>
<p3>...</p3>
<d3/>

其中pn是具有可能的子元素和其他东西的元素，并且dn指示包装p标记的HTML DIV标记应该从哪里开始，但是没有相应的结束标记，这仅由下一个dn标记隐式指示。所需的HTML输出是：

<div>
<p1>...</p1>
<p2>...</p2>
</div>
<div>
<p3>...</p3>
</div>

我编写了一个XSLT来动态地介绍<div>和</div>标签，使用以下内容：

<xsl:text disable-output-escaping="yes">&lt;div&gt;</xsl:text>

和

<xsl:text disable-output-escaping="yes">&lt;/div&gt;</xsl:text>

这适用于Safari，但它在FireFox上失败，这让我怀疑它不是正确的方法。你有更好的想法可以在每个浏览器上运行吗？

提前多多感谢。

Answer 1

您可以使用称为＆＃34; 兄弟递归＆＃34;的技术。

给出一个格式良好的输入，例如：

<强> XML

<root>
    <d1/>
    <p1>a</p1>
    <p2>b</p2>
    <d2/>
    <p3>c</p3>
    <d3/>
</root>

以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="html"/>

<xsl:template match="/root">
    <body>
        <xsl:apply-templates select="*[starts-with(name(), 'd')][position()!=last()]"/>
    </body>
</xsl:template>

<xsl:template match="*[starts-with(name(), 'd')]">
    <div>
        <xsl:apply-templates select="following-sibling::*[1][not(starts-with(name(), 'd'))]"/>
    </div>
</xsl:template>

<xsl:template match="/root/*[not(starts-with(name(), 'd'))]">
    <xsl:copy-of select="."/>
    <xsl:apply-templates select="following-sibling::*[1][not(starts-with(name(), 'd'))]"/>
</xsl:template>

</xsl:stylesheet>

将返回：

<body>
   <div>
      <p>a</p>
      <p>b</p>
   </div>
   <div>
      <p>c</p>
   </div>
</body>

Answer 2

Firefox不支持disable-output-escaping，因为它没有序列化结果树。问题是分组问题，解决问题的一种方法是使用密钥：

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output indent="yes"/>

<xsl:key name="group" match="body/*[not(starts-with(local-name(), 'd'))]" use="generate-id(preceding-sibling::*[starts-with(local-name(), 'd')][1])"/>

<xsl:template match="body">
    <xsl:copy>
        <xsl:apply-templates select="*[starts-with(local-name(), 'd')]"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[starts-with(local-name(), 'd')]">
    <div>
        <xsl:copy-of select="key('group', generate-id())"/>
    </div>
</xsl:template>
</xsl:transform>

但是在样本结束时会创建一个空的div，因此您可能希望将最后一个模板更改为

<xsl:template match="*[starts-with(local-name(), 'd')]">
    <xsl:if test="key('group', generate-id())">
      <div>
        <xsl:copy-of select="key('group', generate-id())"/>
      </div>
    </xsl:if>
</xsl:template>

使用XSLT即时添加HTML标记

2 个答案: