Question

如何使用elisp获取多个列表的交集？我是一个elisp新手，但我想象有一些内置函数或使用reduce的更好的解决方案。我把它拼凑在一起，但看起来过于复杂。

;; get the intersection of these lists
;; result should be (3 4 5)
(setq test '((0 1 2 3 4 5) (2 3 4 5 6) (3 4 5 6 7)))

(require 'cl-lib)
(cl-remove-if-not
 (lambda (x) (cl-every
         (lambda (y) (> (length (memq x y) ) 0 ) )
         (cdr test) ) )
 (car test) )
;; ( 3 4 5)

Answer 1

有cl-intersection只需要两个操作数：

(cl-intersection '(0 1 2 3 4 5) '(2 3 4 5 6))

您可以使用它来定义自己的交叉点：

(defun my-intersection(l)
    (cond ((null l) nil)
          ((null (cdr l)) (car l))
          (t (cl-intersection (car l) (my-intersection (cdr l))))))

(my-intersection '((0 1 2 3 4 5) (2 3 4 5 6) (3 4 5 6 7)))

<强>更新

感谢下面的@Tobias评论，您可以在新函数中使用cl-intersection的相同关键字参数，即（:test :test-not :key）并将它们传播到递归内的所有调用

这是扩展版本：

(defun my-intersection(l &rest cl-keys)
    (cond ((null l) nil)
          ((null (cdr l)) (car l))
          (t (apply 'cl-intersection (car l) (apply 'my-intersection (cdr l) cl-keys) cl-keys))))

Answer 2

安装dash第三方列表操作库（按照instructions进行安装）。然后你需要：

(-reduce '-intersection '((1 2 3 4) (2 3 4 5) (3 4 5 6))) ; => (3 4)

如果您需要一个接受可变数量列表的函数，而不是单个列表列表，请使用&rest关键字将其包装在函数中，如下所示：

(defun -intersection* (&rest list-of-lists)
  (-reduce '-intersection list-of-lists))
;; (-intersection* '(1 2 3 4) '(2 3 4 5) '(3 4 5 6)) ; => (3 4)

如果是第一次使用-reduce，它就是一个“折叠”函数：它采用二元函数，一个元素列表，并将它们一次缩减为最终结果一个列表元素。 This answer解释了背后的概念。

elisp中多个列表的交集

2 个答案: