Question

我在备忘录中有这样的行：

111111.kll
222222.kll

我需要从每一行中删除最后4个字符以获得结果，如：

111111
222222

Answer 1

使用for loop，您可以迭代这些行。使用copy，您可以获取一行的一部分并将其分配回该行：

for i := 0 to Memo1.Lines.Count - 1 do
  Memo1.Lines[i] := Copy(Memo1.Lines[i], 1, Length(Memo1.Lines[i]) - 4);

现在，更改备忘录的行不是很快，所以如果你有很多行，你可能想要使用字符串列表。您可以处理字符串列表中的所有行，并在完成后仅将它们放回备忘录中。这样，备忘录的内容只改变了一次：

var
  i: Integer;
  sl: TStringList;
begin
  sl := TStringList.Create;
  try
    sl.Text := Memo1.Text;
    for i := 0 to sl.Count - 1 do
      sl[i] := Copy(sl[i], 1, Length(sl[i]) - 4);
    Memo1.Text := sl.Text;
  finally
    sl.Free;
  end;
end;

Answer 2

作为GolezTrol解决方案的替代方案，您可以直接操作备忘录内容，而不是先在内存中复制它：

var
  i, LineStart, LineLen: Integer;
begin
  Memo1.Lines.BeginUpdate;
  try
    for i := 0 to Memo1.Lines.Count - 1 do
    begin
      LineStart := Memo1.Perform(EM_LINEINDEX, i, 0);
      LineLen := Memo1.Perform(EM_LINELENGTH, LineStart, 0);
      Memo1.Perform(EM_SETSEL, LineStart + LineLen - 4, LineStart + LineLen);
      Memo1.SelText := '';
    end;
  finally
    Memo1.Lines.EndUpdate;
  end;
end;

Answer 3

嗯，有一个特定的函数来替换字符。如果你想删除＆＃34; .kll＆＃34;例如，不需要使用循环。

  Memo1.Lines.Text := StringReplace(Memo1.Lines.Text,'.kll','',[rfReplaceAll, rfIgnoreCase]);

希望它有所帮助！

Delphi 7从备忘录行中删除了一些字符

3 个答案: