Question

目前正在做的事情：

通过压缩文件/目录来测试功能。断言它存在。
使用:zip.t和:zip.tt让它列出zip文件夹的内容，看看它是否是我所期待的。

不知怎的，我想我错过了一些东西。用:zip.table进行测试会更好吗？该功能看起来令人困惑。有人可以举例说明如何使用它吗？下面是我得到的输出示例，但我无法弄清楚如何将其变成测试？ md5sum对zip档案是一个更好的测试吗？

iex(4)> :zip.table('testing.zip')
{:ok,
 [{:zip_comment, []},
  {:zip_file, 'mix.exs',
   {:file_info, 930, :regular, :read_write, {{2015, 7, 15}, {2, 11, 9}},
    {{2015, 7, 15}, {2, 11, 9}}, {{2015, 7, 15}, {2, 11, 9}}, 54, 1, 0, 0, 0, 0,
    0}, [], 0, 444},
  {:zip_file, 'mix.lock',
   {:file_info, 332, :regular, :read_write, {{2015, 7, 15}, {2, 9, 6}},
    {{2015, 7, 15}, {2, 9, 6}}, {{2015, 7, 15}, {2, 9, 6}}, 54, 1, 0, 0, 0, 0,
    0}, [], 481, 152}]}

Answer 1

来自Erlang的:zip模块并不是很容易使用，我会尝试为你分解它。

首先，我们需要从Erlang开始按顺序对zip_file记录进行适当的表示才能正确使用它。否则，我们必须使用 lot 元素对元组进行匹配，这会不必要地混乱我们的代码。以下模块主要基于the File.Stat implementation from Elixir，并允许我们使用简单的点表示法访问那些难以处理的元组中的值。

require Record

defmodule Zip.File do
  record = Record.extract(:zip_file, from_lib: "stdlib/include/zip.hrl")
  keys   = :lists.map(&elem(&1, 0), record)
  vals   = :lists.map(&{&1, [], nil}, keys)
  pairs  = :lists.zip(keys, vals)

  defstruct keys

  def to_record(%Zip.File{unquote_splicing(pairs)}) do
    {:zip_file, unquote_splicing(vals)}
  end

  def from_record(zip_file)
  def from_record({:zip_file, unquote_splicing(vals)}) do
    %Zip.File{unquote_splicing(pairs)}
    |> Map.update!(:info, fn(info) -> File.Stat.from_record(info) end)
  end
end

我们现在可以围绕Erlang zip模块构建一个小包装器类。它不包括所有方法，只包括我们在这里使用的方法。我还添加了一个list_files/1函数，它只返回文件，不包括列表中的目录和注释。

defmodule Zip do
  def open(archive) do
    {:ok, zip_handle} = :zip.zip_open(archive)
    zip_handle
  end

  def close(zip_handle) do
    :zip.zip_close(zip_handle)
  end

  def list_dir(zip_handle) do
    {:ok, result} = :zip.zip_list_dir(zip_handle)
    result
  end

  def list_files(zip_handle) do
    list_dir(zip_handle)
    |> Enum.drop(1)
    |> Enum.map(&Zip.File.from_record/1)
    |> Enum.filter(&(&1.info.type == :regular))
  end
end

假设我们有以下用于测试的zip存档：

cd /tmp
touch foo bar baz
zip archive.zip foo bar baz

现在您可以在zip存档中声明文件名：

test "files are in zip" do
  zip = Zip.open('/tmp/archive.zip')
  files = Zip.list_files(zip) |> Enum.map(&(&1.name))
  Zip.close(zip)
  assert files == ['foo', 'bar', 'baz']
end

我将在zip存档上留下进一步的操作和断言供您实施，并希望这可以让您开始。

Answer 2

您表示要验证zip文件及其内容。虽然这部分是Elixir / Erlang问题，但它也有点超出了这个简单的背景。这是我的建议：

创建所有文件的列表，并为每个文件创建校验和文件。将它保存在某个地方。
拉上整个东西。
将zip中的文件解压缩到其他目录。
计算解压缩目录中的文件 - 如果是文件数不一样，测试失败。
检查根据步骤1中创建的列表提取的文件列表。如果文件列表不匹配，则测试失败。
计算所有文件的校验和。比较校验和针对步骤1中存储的校验和。如果它们不匹配，请进行测试失败。

所有这一切，这让我感到非常毫无意义，因为基本上你正在测试的是Erlang zip库。如果Erlang zip库中存在缺陷，那么人们就已经抱怨了很长时间，并且只需谷歌搜索它就能发现存在缺陷。

也就是说，虽然你可以为此编写单元测试，但这对我来说是浪费时间。

在Elixir中断言zip存档内容的最佳方法是什么？

2 个答案: