Question

我目前正在尝试为REST服务设置集成测试框架，该服务构建于：

弹簧引导
摇篮
Jetty

我能够使用 spring-boot集成测试框架以及 spring-boot junit runner 来调出应用程序上下文并成功运行测试。

我接下来要做的是做一个 gradle任务，它将执行以下操作：

制造罐子（不是战争）
启动jetty并部署jar
针对此jar运行一组测试用例。
停止码头

=＆GT;我尝试使用＆＃39; 码头＆＃39;插入。但它似乎不支持jar文件 =＆GT;然后我尝试使用 JavaExec任务来运行jar然后运行测试，但是在测试完成后我无法找到一种直接的方法来停止jar进程。
=＆GT;与Exec类型任务相同的问题。

所以，我有两个问题：

有没有办法使用gradle实现上述形式的集成测试。
建议使用这种集成测试方式还是有更好的方法？

非常感谢任何想法和见解。

谢谢，

Answer 1

有不同的方法可以达到你想要的效果。我在客户端帮助的方法依赖于Spring Boot Actuator提供的/ shutdown URL。重要如果您使用此方法，请务必disable or secure the /shutdown endpoint进行制作。

在构建文件中，您有两个任务：

task startWebApp(type: StartApp) {
    dependsOn 'assemble'
    jarFile = jar.archivePath
    port = 8080
    appContext = "MyApp"
}

task stopWebApp(type: StopApp) {
    urlPath = "${startWebApp.baseUrl}/shutdown"
}

您应该确保集成测试依赖于startWebApp任务，并且应该通过stop任务完成它们。所以像这样：

integTest.dependsOn "startWebApp"
integTest.finalizedBy "stopWebApp"

当然，您还需要创建自定义任务实现：

class StartApp extends DefaultTask {
    static enum Status { UP, DOWN, TIMED_OUT }

    @InputFile
    File jarFile

    @Input
    int port = 8080

    @Input
    String appContext = ""

    String getBaseUrl() {
        return "http://localhost:${port}" + (appContext ? '/' + appContext : '')
    }

    @TaskAction
    def startApp() {
        logger.info "Starting server"
        logger.debug "Application jar file: " + jarFile

        def args = ["java",
                "-Dspring.profiles.active=dev",
                "-jar",
                jarFile.path]
        def pb = new ProcessBuilder(args)
        pb.redirectErrorStream(true)

        final process = pb.start()
        final output = new StringBuffer()
        process.consumeProcessOutputStream(output)

        def status = Status.TIMED_OUT
        for (i in 0..20) {
            Thread.sleep(3000)

            if (hasServerExited(process)) {
                status = Status.DOWN
                break
            }

            try {
                status = checkServerStatus()
                break
            }
            catch (ex) {
                logger.debug "Error accessing app health URL: " + ex.message
            }
        }

        if (status == Status.TIMED_OUT) process.destroy()

        if (status != Status.UP) {
            logger.info "Server output"
            logger.info "-------------"
            logger.info output.toString()
            throw new RuntimeException("Server failed to start up. Status: ${status}")
        }
    }

    protected Status checkServerStatus() {
        URL url = new URL("$baseUrl/health")
        logger.info("Health Check --> ${url}")
        HttpURLConnection connection = url.openConnection()
        connection.readTimeout = 300

        def obj = new JsonSlurper().parse(
            connection.inputStream,
            connection.contentEncoding ?: "UTF-8")
        connection.inputStream.close()
        return obj.status == "UP" ? Status.UP : Status.DOWN
    }

    protected boolean hasServerExited(Process process) {
        try {
            process.exitValue()
            return true
        } catch (IllegalThreadStateException ex) {
            return false
        }
    }
}

请注意，在线程上启动服务器很重要，否则任务永远不会结束。停止服务器的任务更简单：

class StopApp extends DefaultTask {

    @Input
    String urlPath

    @TaskAction
    def stopApp(){
        def url = new URL(urlPath)
        def connection = url.openConnection()
        connection.requestMethod = "POST"
        connection.doOutput = true
        connection.outputStream.close()
        connection.inputStream.close()
    }
}

它基本上向/ shutdown URL发送一个空POST以停止正在运行的服务器。

使用gradle

1 个答案: