Question

在ANT中有一个关于此问题的解决方案，但我们如何通过gradle实现这一目标？是否可以通过编译后编织来实现。意思是用lombok编译来获取所有生成的delombok代码，然后在这个生成的delombok代码上编织方面而不是aspectJ擦除它？

以下这些SO帖子似乎没有任何关于如何解决这个问题的结论？

Lombok does not work with AspectJ? Gradle + RoboBinding with AspectJ + Lombok are not compatible together

DiscussionThread http://aspectj.2085585.n4.nabble.com/AspectJ-with-Lombok-td4651540.html

谢谢你， Setzer

Answer 1

实际上这个问题已经很老了，但是由于遇到了同样的问题，我想分享我的解决方案。

我找到的最佳解决方案是this。实际上，在Gradle中没有对AspectJ的内置支持，现有的插件（例如，Gradle AspectJ插件）不能与Lombok一起使用。因此，解决方案是手动在代码中启用编译时编织。准备好去Java 8的gradle.build就是这个

buildscript {
    repositories {
        jcenter()
        maven { url 'http://repo.spring.io/plugins-release' }
    }

    dependencies {

    }
}

apply plugin: 'idea' // if you use IntelliJ
apply plugin: 'java'

ext {
    aspectjVersion = '1.8.9'
    springVersion = '4.2.1.RELEASE'
}

repositories {
    jcenter()
}

configurations {
    ajc
    aspects
    compile {
        extendsFrom aspects
    }
}

dependencies {
    compile "org.aspectj:aspectjrt:$aspectjVersion"
    compile "org.aspectj:aspectjweaver:$aspectjVersion"

    ajc "org.aspectj:aspectjtools:$aspectjVersion"
    aspects "org.springframework:spring-aspects:$springVersion"
}

def aspectj = { destDir, aspectPath, inpath, classpath ->
    ant.taskdef(resource: "org/aspectj/tools/ant/taskdefs/aspectjTaskdefs.properties",
            classpath: configurations.ajc.asPath)

    ant.iajc(
            maxmem: "1024m", fork: "true", Xlint: "ignore",
            destDir: destDir,
            aspectPath: aspectPath,
            inpath: inpath,
            classpath: classpath,
            source: project.sourceCompatibility,
            target: project.targetCompatibility
    )
}

compileJava {
    doLast {
        aspectj project.sourceSets.main.output.classesDir.absolutePath,
                configurations.aspects.asPath,
                project.sourceSets.main.output.classesDir.absolutePath,
                project.sourceSets.main.runtimeClasspath.asPath
    }
}

compileTestJava {
    dependsOn jar

    doLast {
        aspectj project.sourceSets.test.output.classesDir.absolutePath,
                configurations.aspects.asPath + jar.archivePath,
                project.sourceSets.test.output.classesDir.absolutePath,
                project.sourceSets.test.runtimeClasspath.asPath
    }
}

您可以在article already mentioned above中找到其他说明。这里给出的build.gradle是文章中给出的更新版本，允许使用Java 8和AspectJ版本1.8.9，此外还删除了所有不必要的东西。

AspectJ + Gradle + Lombok不起作用

1 个答案: