Question

我似乎总是努力编写DCG来解析输入文件。但它似乎应该很简单？是否有任何提示或技巧可以考虑这个问题？

举一个具体的例子，假设我要解析一个fasta文件。（https://en.wikipedia.org/wiki/FASTA_format）。我想在反向跟踪中阅读每个描述和每个序列。

:- use_module(library(pio)).
:- use_module(library(dcg/basics)).
:- portray_text(true).
:- set_prolog_flag(double_quotes, codes).
:- set_prolog_flag(back_quotes,string).

fasta_file([]) -->[].
fasta_file([Section|Sections]) -->
   fasta_section(Section),
   fasta_file(Sections).


fasta_section(Section) -->
    fasta_description(Description),
    fasta_seq(Sequence),
    {Section =.. [section,Description,Sequence]}.

fasta_description(Description) -->
    ">",
    string(Description),
    {no_gt(Description),
     no_nl(Description)}.


fasta_seq([]) --> [].
fasta_seq(Seq) -->
    nt([S]),
    fasta_seq(Ss),
    {S="X"->Seq =Ss;Seq=[S|Ss]}.

 nt("A") --> "A".
 nt("C") --> "C".
 nt("G") --> "G".
 nt("T") --> "T".
 nt("X") --> "\n".

 no_gt([]).
 no_gt([E|Es]):-
     dif([E],">"),
     no_gt(Es).

 no_nl([]).
 no_nl([E|Es]):-
     dif([E],"\n"),
     no_nl(Es).

现在这显然是错误的。我想要的行为是

 ?-phrase(fasta_section(S),">frog\nACGGGGTACG\n>duck\nACGTTAG").
 S = section("frog","ACGGGGTACG");
 S = section("duck","ACGTTAG");
 false.

但是如果我做了phrase(fasta_file(Sections),">frog\nACGGGGTACG\n>duck\nACGTTAG). Sections与section / 2s列表统一，这就是我想要的，但我当前的代码看起来很hacky-我如何处理换行符例如。

Answer 1

当然，有“小”打字问题：

nt("A") -->"A",
nt("C") -->"C",
nt("G") -->"G",
nt("T") -->"T".

应该是

nt("A") -->"A".
nt("C") -->"C".
nt("G") -->"G".
nt("T") -->"T".

无论如何，我在调试DCG时遇到了问题，我编写了一个解析器来加载Prolog一个MySQL转储（纯SQL，真的），当出现意外情况时很痛苦，比如转义字符串或UTF8（？）奇怪的编码被发现了。

我建议使用短语/ 3，看看是否有一个不可解决的尾巴。此外，可以帮助在已知的，表现良好的序列之后放置一些调试输出。

当然，我假设您已经尝试使用SWI-Prolog调试器。

另外，要小心

...
dif([E],">"),
...

你是否设置了关于双引号的适当标志？在DCG主体中，重写机制负责匹配，但默认情况下，SWI-Prolog中的一系列代码不匹配双引号字符串......

修改的

我认为这不会解决你对一般战略的疑虑......无论如何，这就是我如何处理这个问题......

fasta_file([]) -->[].
fasta_file([Section|Sections]) -->
    fasta_section(Section),
    fasta_file(Sections).

fasta_section(section(Description,Sequence)) -->
    fasta_description(Description),
    fasta_seq(SequenceCs), {atom_codes(Sequence, SequenceCs)}, !.

fasta_description(Description) -->
    ">", string(DescriptionCs), "\n", {atom_codes(Description, DescriptionCs)}.

fasta_seq([S|Seq]) --> nt(S), fasta_seq(Seq).
fasta_seq([]) --> "\n" ; []. % optional \n at EOF

nt(0'A) --> "A".
nt(0'C) --> "C".
nt(0'G) --> "G".
nt(0'T) --> "T".

现在

?- phrase(fasta_file(S), `>frog\nACGGGGTACG\n>duck\nACGTTAG`).
S = [section(frog, 'ACGGGGTACG'), section(duck, 'ACGTTAG')] ;
false.

注意：fasta_seq // 1子句的顺序很重要，因为它实现了'急切'解析 - 主要是为了提高效率。正如我所说，我必须解析SQL，几个MB很常见。

修改的

?- phrase((string(_),fasta_section(S)), `>frog\nACGGGGTACG\n>duck\nACGTTAG`,_).
S = section(frog, 'ACGGGGTACG') ;
S = section(duck, 'ACGTTAG') ;
false.

fasta_section // 1意味着匹配一个确定的序列。要全力以赴回溯，我们必须提供一个回溯点。在这种情况下，来自库（dcg / basics）的字符串// 1执行作业

为文件输入创建dcg的一般模式是什么？

1 个答案: