Question

我有这样的XML：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <users>1, 2, 3</users>
</root>

我想将ID 1,2,3转换为相应的名称，例如＆＃34; Albert＆＃34;，＆＃34; Brown＆＃34;，＆＃34; Clark＆＃34;，并将它们连接起来＆＃34 ;;＆＃34 ;. ID和名称是固定的，因此我只需要将名称逐个映射到ID。我想以这种方式使用XSLT 1.0和结果XML：

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <users>Albert;Brown;Clark</users>
</root>

我是XSL的新手，所以有什么建议可以帮助我完成这项工作吗？非常感谢！

Answer 1

这里实际上存在两个问题：（1）如何标记字符串输入，以及（2）如何查找每个标记代码的相应名称。试试这种方式：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:exsl="http://exslt.org/common"
extension-element-prefixes="exsl">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="users">
    <user code="1">Albert</user>
    <user code="2">Brown</user>
    <user code="3">Clark</user>
</xsl:variable>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="users">
    <xsl:copy>
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="."/>
        </xsl:call-template>        
    </xsl:copy>
</xsl:template>

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="delimiter" select="', '"/>
    <xsl:variable name="code" select="substring-before(concat($text, $delimiter), $delimiter)" />
    <xsl:variable name="name" select="exsl:node-set($users)/user[@code=$code]" /> 
    <xsl:choose>
        <xsl:when test="$name">
            <xsl:value-of select="$name"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="concat('No user found for code', $code)"/>
        </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="contains($text, $delimiter)">
        <xsl:text>;</xsl:text>
        <!-- recursive call -->
        <xsl:call-template name="tokenize">
            <xsl:with-param name="text" select="substring-after($text, $delimiter)"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

注意：您可以使用外部XML文档来保存代码索引并从中查找名称，而不是变量，例如：请参阅：XSLT- Copy node from other XML file, based on matching node value

在XSL中，如何从逗号中拆分字符串并将拆分的子字符串替换为其他字符串？

1 个答案: