Question

给定一个字符串，如何生成它的所有分区（显示为用逗号分隔的较小字符串）？
另外，长度为n？

的字符串的分区总数是多少

以下将给出结果，但对长字符串不好。

String: CODE

C,O,D,E
C,O,DE
C,OD,E
C,ODE
CO,D,E
CO,DE
COD,E


String: PEACE

P,E,A,C,E
P,E,A,CE
P,E,AC,E
P,E,ACE
P,EA,C,E
P,EA,CE
P,EAC,E
PE,A,C,E
PE,A,CE
PE,AC,E
PE,ACE
PEA,C,E
PEA,CE

Sub getAllComb()

    oriStr = TextBox1.Text
    Dim tmp = ""
    Dim k = 0
    For i = 0 To oriStr.Length
        For j = 1 To 3
            'tmp = Mid(oriStr, i, j)
            Try
                tmp1(k) = oriStr.Substring(i, j)
                k = k + 1
                'tmp = oriStr.Substring(i, j)
                'Debug.Print(tmp)
            Catch ex As Exception
                'Debug.Print("Error>>>>" + ex.Message)
                Exit For
            End Try

        Next
    Next
    tmp = ""
    For i = 0 To k
        Debug.Print(i.ToString + "<i " + tmp1(i))
        tmp = tmp & tmp1(i) & vbCrLf
    Next
    'MessageBox.Show(tmp) 


    Dim tmpAll1 = ""

    tmpAll1 = addFunclen4(k)


    MessageBox.Show(tmpAll1)
    Debug.Print(tmpAll1)

    TextBox1.Text = oriStr & vbCrLf & vbCrLf & tmpAll1
End Sub



Function addFunclen4(k As Integer) As String
    Dim retVal = ""
    Dim tmp = ""
    Dim tmpAll = ""
    Dim tmpStr = ""
    Dim tmpAll1 = ""
    For i = 0 To k
        For i1 = 0 To k
            For i2 = 0 To k
                For i3 = 0 To k
                    For i4 = 0 To k

                        tmp = Form1.tmp1(i) + Form1.tmp1(i1) + Form1.tmp1(i2) + Form1.tmp1(i3) + Form1.tmp1(i4)
                        If Form1.tmp1(i) <> "" Then
                            If tmp = Form1.oriStr Then
                                tmpStr = Form1.tmp1(i) + "," + Form1.tmp1(i1) + "," + Form1.tmp1(i2) + "," + Form1.tmp1(i3) + "," + Form1.tmp1(i4)
                                Do While tmpStr.Contains(",,") = True
                                    tmpStr = Replace(tmpStr, ",,", ",")
                                Loop
                                If Mid(tmpStr, tmpStr.Length, 1) = "," Then
                                    tmpStr = Mid(tmpStr, 1, tmpStr.Length - 1)
                                End If

                                If tmpAll1.Contains(tmpStr) = False Then
                                    tmpAll1 = tmpAll1 + tmpStr + vbCrLf
                                End If
                            End If

                        End If
                    Next
                Next
            Next
        Next

    Next
    retVal = tmpAll1

    Return retVal
End Function

Answer 1

我估计总共[2 ^（n-1） - 1]：
（n-1）位置用逗号，2“状态”（逗号或不用逗号），-1表示没有逗号的琐碎案例。

更简单的算法是遍历案例数并使用二进制表示来确定是否在每个位置放置逗号。

例如（TextBox，Button和ListBox的简单形式）：

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    ListBox1.Items.Clear()
    Dim s As String = TextBox1.Text

    If s.Length < 2 Then
        MessageBox.Show("Enter a longer string")
        Return
    End If

    For i = 1 To Math.Pow(2, s.Length - 1) - 1
        Dim result As String = s(0)
        For j = 1 To s.Length - 1
            result = result & CommaOrNot(i, j) & s(j)
        Next
        ListBox1.Items.Add(result)
    Next
End Sub

Private Function CommaOrNot(i As Integer, j As Integer) As String
    If (i And Math.Pow(2, j - 1)) = Math.Pow(2, j - 1) Then
        Return ","
    Else
        Return ""
    End If
End Function

Answer 2

我真的很喜欢Fruitbat的做法。这是一个替代版本，使用稍微不同的机制来表示二进制数，以及如何确定是否应该包含逗号：

Public Class Form1

    Private combinations As List(Of String)

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
        Dim s As String = TextBox1.Text
        If s.Length < 2 Then
            MessageBox.Show("Enter a longer string")
            Exit Sub
        End If

        Button1.Enabled = False
        ListBox1.DataSource = Nothing
        ListBox1.Items.Clear()
        ListBox1.Items.Add("Generating combinations...")
        BackgroundWorker1.RunWorkerAsync(s)
    End Sub

    Private Sub BackgroundWorker1_DoWork(sender As Object, e As System.ComponentModel.DoWorkEventArgs) Handles BackgroundWorker1.DoWork
        Dim s As String = e.Argument
        Dim combinations As New List(Of String)

        Dim binary() As Char
        Dim values() As Char = s.ToCharArray
        Dim max As Integer = Convert.ToInt32(New String("1", s.Length - 1), 2)
        Dim sb As New System.Text.StringBuilder
        For i As Integer = 0 To max
            sb.Clear()
            binary = Convert.ToString(i, 2).PadLeft(values.Length, "0").ToCharArray
            For j As Integer = 0 To values.Length - 1
                sb.Append(If(binary(j) = "0", "", ","))
                sb.Append(values(j))
            Next
            combinations.Add(sb.ToString)
        Next

        e.Result = combinations
    End Sub

    Private Sub BackgroundWorker1_RunWorkerCompleted(sender As Object, e As System.ComponentModel.RunWorkerCompletedEventArgs) Handles BackgroundWorker1.RunWorkerCompleted
        combinations = e.Result
        ListBox1.Items.Clear()
        ListBox1.Items.Add("Generating combinations...Done!")
        ListBox1.Items.Add("Adding Results...one moment please!")
        Application.DoEvents()

        ListBox1.DataSource = Nothing
        ListBox1.DataSource = combinations
        Button1.Enabled = True
        MessageBox.Show("Done!")
    End Sub

End Class

如何在VB.Net中生成分区字符串的所有组合

2 个答案: