Question

我正在尝试复制一个元素，它的相关兄弟（它们以这样的顺序存在）成为一个新的共享父级，但我很难做到这一点 - 我的XSLT知识是有限的。

给出以下XML（可以认为是HTML）：

<root>
    <p />
    <p />
    <heading />
    <content />
    <image />
    <p />
    <p />
    <heading />
    <p />
    <p />
    <image />
    <p />
    <p />
    <heading />
    <content />
    <image />
    <p />
    <p />
    <p />
</root>

我正在尝试创建此结构：

<root>
    <p />
    <p />
    <wrapper>
        <heading />
        <content />
        <image />
    </wrapper>
    <p />
    <p />
    <heading />
    <p />
    <p />
    <image />
    <p />
    <p />
    <wrapper>
        <heading />
        <content />
        <image />
    </wrapper>
    <p />
    <p />
    <p />
</root>

这是我的样式表的开始，首先将每个节点复制到输出中：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <xsl:output method="html" encoding="UTF-8" />

    <xsl:template match="node()">
        <xsl:copy>
            <xsl:copy-of select="@*" disable-output-escaping="yes" />
            <xsl:apply-templates select="node()" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="//heading[following-sibling::content][following-sibling::image]">
    </xsl:stylesheet>

</xsl:stylesheet>

但在此之后，我不确定（概念上）如何处理下一阶段。我需要将每组<heading />，<content />和<image />节点移动到一个新元素中。

非常感谢任何帮助。

Answer 1

我需要移动每组<heading />, <content /> and <image /> 将节点转换为新元素。

这样的事情对你有用吗？

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="heading[following-sibling::*[1][self::content] and following-sibling::*[2][self::image]]">
    <wrapper>
        <xsl:copy-of select=". | following-sibling::*[1] | following-sibling::*[2]"/>
    </wrapper>
</xsl:template>

<xsl:template match="content[preceding-sibling::*[1][self::heading] and following-sibling::*[1][self::image]]"/>
<xsl:template match="image[preceding-sibling::*[1][self::content] and preceding-sibling::*[2][self::heading]]"/>

</xsl:stylesheet>

将节点及其相关的兄弟节点移动到新的父节点

1 个答案: