Question

我正在编写一个程序，根据许多复杂的规则验证复杂的数据结构。它输入数据并输出一条消息列表，指出数据存在问题。

按照以下思路思考：

import Control.Monad (when)
import Control.Monad.Writer (Writer, tell)

data Name = FullName String String | NickName String
data Person = Person { name :: Name, age :: Maybe Int }

data Severity = E | W | C   -- error/warning/comment
data Message = Message { severity :: Severity, code :: Int, title :: String }
type Validator = Writer [Message]

report :: Severity -> Int -> String -> Validator ()
report s c d = tell [Message s c d]

checkPerson :: Person -> Validator ()
checkPerson person = do
  case age person of
    Nothing -> return ()
    Just years -> do
      when (years < 0) $ report E 1001 "negative age"
      when (years > 200) $ report W 1002 "age too large"
  case name person of
    FullName firstName lastName -> do
      when (null firstName) $ report E 1003 "empty first name"
    NickName nick -> do
      when (null nick) $ report E 1004 "empty nickname"

对于文档，我还想编译该程序可以输出的所有消息的列表。也就是说，我想获得价值：

[ Message E 1001 "negative age"
, Message W 1002 "age too large"
, Message E 1003 "empty first name"
, Message E 1004 "empty nickname"
]

我可以将消息从checkPerson移到一些外部数据结构中，但是当我们在使用它们的地方定义消息时，我喜欢它。

我可以（也可能应该）在编译时从AST中提取消息。

但Haskell吹捧的灵活性让我思考：我可以在运行时实现吗？也就是说，我可以写一个函数

allMessages :: (Person -> Validator ()) -> [Message]

这样allMessages checkPerson会给我上面的列表吗？

当然，checkPerson和Validator 无需保持不变。

我几乎（不太）可以看到我如何制作一个自定义Validator monad，其中“后门”会以某种“反射模式”运行checkPerson，遍历所有路径并返回遇到所有Message个。我必须编写一个自定义when函数，在某些情况下会知道忽略它的第一个参数（哪些？）。所以，一种DSL。也许我甚至可以模仿模式匹配？

所以：我可以做这样的事情，如何以及我必须牺牲什么？

即使它们不完全符合上述说明，也请随意提出任何解决方案。

Answer 1

这种半静态分析基本上就是为箭头发明的。那就让我们做一个箭！我们的箭头基本上只是一个Writer动作，但它会记住它在任何特定时刻可能吐出的消息。首先，一些样板：

{-# LANGUAGE Arrows #-}

import Control.Arrow
import Control.Category
import Control.Monad.Writer
import Prelude hiding (id, (.))

现在，上述类型：

data Validator m a b = Validator
    { possibleMessages :: [m]
    , action :: Kleisli (Writer m) a b
    }

runValidator :: Validator m a b -> a -> Writer m b
runValidator = runKleisli . action

有一些简单的实例可以实施。特别感兴趣的是：两个验证器的组合会记住第一个动作和第二个动作的消息。

instance Monoid m => Category (Validator m) where
    id = Validator [] id
    Validator ms act . Validator ms' act' = Validator (ms ++ ms') (act . act')

instance Monoid m => Arrow (Validator m) where
    arr f = Validator [] (arr f)
    first (Validator ms act) = Validator ms (first act)

instance Monoid m => ArrowChoice (Validator m) where
    left (Validator ms act) = Validator ms (left act)

所有魔法都在实际让你报告的操作中：

reportWhen :: Monoid m => m -> (a -> Bool) -> Validator m a ()
reportWhen m f = Validator [m] (Kleisli $ \a -> when (f a) (tell m))

当您即将输出可能的消息时，会注意到此操作，并记下它。让我们复制您的类型，并展示如何将checkPerson编码为箭头。我已经简化了你的消息了一些，但没有什么重要的是不同的 - 在这个例子中只需要更少的语法开销。

type Message = String
data Name = FullName String String | NickName String -- http://www.kalzumeus.com/2010/06/17/falsehoods-programmers-believe-about-names/
data Person = Person { name :: Name, age :: Maybe Int }

checkPerson :: Validator Message Person ()
checkPerson = proc person -> do
    case age person of
        Nothing -> returnA -< ()
        Just years -> do
            "negative age"  `reportWhen` (<  0) -< years
            "age too large" `reportWhen` (>200) -< years
    case name person of
        FullName firstName lastName -> do
            "empty first name" `reportWhen` null -< firstName
        NickName nick -> do
            "empty nickname"   `reportWhen` null -< nick

我希望您同意这种语法与您最初编写的内容相去甚远。让我们在ghci中看到它：

> runWriter (runValidator checkPerson (Person (NickName "") Nothing))
((),"empty nickname")
> possibleMessages checkPerson 
["empty nickname","empty first name","age too large","negative age"]

我可以在运行时从Haskell程序中反映消息吗？

1 个答案: