Question

我已经证明我可以使用Delphi 2010从其GUID获取接口的名称（例如，IMyInterface转换为字符串'IMyInterface'。我想在Delphi 7中实现这一点（为了兼容性）。这是否可能？或者是否存在基本的编译器限制。

Answer 1

是的，你可以得到它，以下显示如何使用IExample类型获取名称。旧的Delphi 7 RTTI是通过TypInfo Unit完成的。

program Project6;
{$APPTYPE CONSOLE}
uses
  SysUtils,TypInfo;

type
  IExample = interface
    ['{4902F666-F3FC-4999-BD8C-F226851201D6}']
    procedure blah;
  end;


begin
  Writeln(GetTypeName(TypeInfo(IExample)));
  readln
end.

刚刚注意到你说你想从GUID中获取它，而不仅仅是类型。这将需要GUID注册表到类型。 Delphi 7中的RTTI可用于获取类型。

以下将采用IExample返回guid。

Writeln(GUIDToString(GetTypeData(TypeInfo(IExample)).Guid));

这是一个示例注册表，它将接口的TypeInfo（）映射到它的GUID。它可以进行优化，但我这样做是为了说明这个概念。

unit Unit11;

interface
uses
  TypInfo,SysUtils, Contnrs;

type

  TGuidMap = class(TObject)
    Guid : TGUID;
    TypeInfo : PTypeInfo;
  end;

procedure RegisterInterface(InterfaceType : PTypeInfo);

function GetInterfaceType(Guid : TGUID) : PTypeInfo;

implementation
var
  GuidMapList : TObjectList;

procedure RegisterInterface(InterfaceType : PTypeInfo);
var
 Map : TGuidMap;
begin
  Map := TGuidMap.Create;
  Map.TypeInfo := InterfaceType;
  Map.Guid := GetTypeData(InterfaceType).Guid;
  GuidMapList.Add(Map);
end;

function GetInterfaceType(Guid : TGUID) : PTypeInfo;
var
 I : Integer;
begin
 result := nil;
 for I := 0 to GuidMapList.Count - 1 do
 begin
   if IsEqualGUID(TGuidMap(GuidMapList.Items[I]).Guid,Guid) then
   begin
     result := TGuidMap(GuidMapList.Items[I]).TypeInfo;
     break;
   end;
 end;
end;

Initialization
 GuidMapList := TObjectList.Create(true);
finalization
 GuidMapList.Free;
end.

要将项目添加到注册表，您可以调用

   RegisterInterface(TypeInfo(IExample));

Answer 2

在Delphi 7中，您应该构建自己的GUID到RTTI（或Name）的映射。这不是像Delphi 2010中那样的RTTI上下文。我广泛使用RIIT并且通常在中心的某个地方的初始化部分“注册”所有有趣的类型，并根据typeinfo指针从那里找到所有类型。这适用于D7，D2007和D2010（但如果您需要创建它，则更有效）。你也可能忘记注册一个类型并想知道为什么无法找到某些东西。

使用Delphi RTTI获取接口的字符串名称

2 个答案: