Question

我是Access的新手，在实施我在另一篇文章中看到的内容时遇到了一些困难。 MS-Access: How to open form in same location/size as closed/previous form?

我想在最后关闭的同一个位置打开我的弹出窗体，并且我创建了一个表（sizpos）来存储位置和大小的4个属性（左，顶，宽，高））和表单（对象）的名称和唯一的ID号。

我需要一些帮助，找出VBA代码，根据close或unload事件中的表单名称存储打开表单的属性。我还需要帮助代码来从表中检索open或load事件上的开始表单的信息。

我尝试在dlookup中使用me.move但没有取得任何成功，但可能没有正确实施。

我想出了几乎适用于报告的以下内容。我无法弄清楚如何从正在打开的报表中提取报表的名称，类似于表单中的me.name函数。我已经注意到那些me.reportname ???

的区域

Private Sub Report_Open(Cancel As Integer)
Dim l As Long
Dim t As Long
l = Nz(DLookup("Left", "SizPos", "Object = 'me.reportname???'"))
t = Nz(DLookup("Top", "SizPos", "Object = 'me.reportname???'"))
Me.Move Left:=l, Top:=t
End Sub

Private Sub Report_Close()
Dim strSQL As String
strSQL = "UPDATE SizPos SET SizPos.Left = " & Me.WindowLeft & ", SizPos.Top = " & Me.WindowTop & " WHERE SizPos.Object = 'me.reportname???';"
CurrentDb.Execute strSQL
End Sub

以下内容适用于表单。

Private Sub Form_Open(Cancel As Integer)
Dim l As Long
Dim t As Long
Dim w As Long
Dim h As Long
l = Nz(DLookup("Left", "SizPos", "Object = '" & Me.Name & "'"))
t = Nz(DLookup("Top", "SizPos", "Object = '" & Me.Name & "'"))
w = Nz(DLookup("Width", "SizPos", "Object = '" & Me.Name & "'"))
h = Nz(DLookup("Height", "SizPos", "Object = '" & Me.Name & "'"))
Me.Move Left:=l, Top:=t, Width:=w, Height:=h
End Sub

Private Sub Form_Close()
DoCmd.Save
Dim strSQL As String
strSQL = "UPDATE SizPos SET SizPos.Left = " & Me.WindowLeft & ", SizPos.Top = " & Me.WindowTop & ", SizPos.Width = " & Me.WindowWidth & ", SizPos.Height = " & Me.WindowHeight & " WHERE SizPos.Object = '" & Me.Name & "';"
CurrentDb.Execute strSQL
End Sub

Answer 1

使用DAO.Recordset代替4 DLookup语句来获取对象大小和位置的值。您也可以稍后使用DAO.Recordset存储它们，而不是构建和执行UPDATE和INSERT语句。

这是我的 sizpos 表：

CREATE TABLE sizpos (
    id COUNTER PRIMARY KEY,
    obj_name TEXT(255) UNIQUE,
    lft INTEGER,
    tp INTEGER,
    wdth INTEGER,
    hght INTEGER
    );

我创建了一个参数查询来获取给定表单或报表名称的存储大小和位置值：

PARAMETERS which_object Text (255);
SELECT s.obj_name, s.lft, s.tp, s.wdth, s.hght
FROM sizpos AS s
WHERE s.form_name=[which_object];

我本可以将其保存为命名查询。但是我创建了一个函数 SelectObjectSettings ，以返回该语句文本。

因此，在表单加载期间，我可以将表单的名称提供给该查询，并打开带有查询结果的DAO.Recordset。然后，如果记录集不为空，请使用记录集的值来设置表单的大小和位置：

Private Sub Form_Load()
    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Dim rs As DAO.Recordset

    Set db = CurrentDb
    Set qdf = db.CreateQueryDef(vbNullString, SelectObjectSettings)
    qdf.Parameters("which_object").Value = Me.Name
    Set rs = qdf.OpenRecordset
    With rs
        If Not (.BOF And .EOF) Then
            Me.Move Left:=!lft, Top:=!tp, Width:=!wdth, Height:=!hght
        End If
    End With

    Set rs = Nothing
    Set qdf = Nothing
    Set db = Nothing

End Sub

注意：如果您有保存的参数查询，则Set qdf可以...

'Set qdf = db.CreateQueryDef(vbNullString, SelectObjectSettings)
Set qdf = db.QueryDefs("YourQueryName")

在表单卸载中，保存表单的大小和位置：

Private Sub Form_Unload(Cancel As Integer)
    Dim db As DAO.Database
    Dim qdf As DAO.QueryDef
    Dim rs As DAO.Recordset

    Set db = CurrentDb
    Set qdf = db.CreateQueryDef(vbNullString, SelectObjectSettings)
    qdf.Parameters("which_object").Value = Me.Name
    Set rs = qdf.OpenRecordset
    With rs
        If (.BOF And .EOF) Then
            ' no existing record for this object; create one
            .AddNew
            !obj_name = Me.Name
        Else
            ' a record exists for this object; edit it
            .Edit
        End If
        !lft = Me.WindowLeft
        !tp = Me.WindowTop
        !wdth = Me.WindowWidth
        !hght = Me.WindowHeight
        .Update
        .Close
    End With

    Set rs = Nothing
    Set qdf = Nothing
    Set db = Nothing

End Sub

打开MS Access表单或报告与上次关闭时相同的位置

1 个答案: