Question

我正在编写一个可能被用户修改的脚本。目前我正在将配置设置存储在脚本中。它以散列哈希的形式存在。

我想防止人们在哈希键中意外使用小写字符，因为这会破坏我的脚本。

检查哈希键并且仅对具有小写字符的任何键发出警告会很简单，但我宁愿自动修复区分大小写。

换句话说，我想将顶级哈希中的所有哈希键转换为大写。

Answer 1

遍历散列并将任何小写的键替换为大写等值，并删除旧的。大致是：

for my $key ( grep { uc($_) ne $_ } keys %hash ) {
    my $newkey = uc $key;
    $hash{$newkey} = delete $hash{$key};
}

Answer 2

安迪的答案是一个很好的答案，除了他uc的每一个键，然后uc如果它不匹配则再次。

这uc一次：

%hash = map { uc $_ => $hash{$_} } keys %hash;

但是既然你谈到用户存储密钥，那么平局是一种更加可靠的方式，即使速度较慢。

package UCaseHash;
require Tie::Hash;

our @ISA = qw<Tie::StdHash>;

sub FETCH { 
    my ( $self, $key ) = @_;
    return $self->{ uc $key };
}

sub STORE { 
    my ( $self, $key, $value ) = @_;
    $self->{ uc $key } = $value;
}

1;

然后在主要：

tie my %hash, 'UCaseHash';

这是一个节目。 tie“魔法”封装了它，因此用户不会在不知不觉中弄乱它。

当然，只要您使用“类”，就可以传入配置文件名并从那里初始化它：

package UCaseHash;
use Tie::Hash;
use Carp qw<croak>;

...

sub TIEHASH { 
    my ( $class_name, $config_file_path ) = @_;
    my $self = $class_name->SUPER::TIEHASH;
    open my $fh, '<', $config_file_path 
        or croak "Could not open config file $config_file_path!"
        ;
    my %phash = _process_config_lines( <$fh> );
    close $fh;
    $self->STORE( $_, $phash{$_} ) foreach keys %phash;
    return $self;
}

您必须将其称为：

tie my %hash, 'UCaseHash', CONFIG_FILE_PATH;

...假设有一些常数CONFIG_FILE_PATH。

Answer 3

这会将多级哈希转换为小写

my $lowercaseghash = convertmaptolowercase(\%hash);

sub convertmaptolowercase(){
    my $output=$_[0];
    while(my($key,$value) = each(%$output)){
        my $ref;
        if(ref($value) eq "HASH"){
            $ref=convertmaptolowercase($value);
        } else {
           $ref=$value;
        }
        delete $output->{$key}; #Removing the existing key
        $key = lc $key;
        $output->{$key}=$ref; #Adding new key
    }
    return $output;
}

如何更改哈希键的大小写？

3 个答案: