Question

我正在研究x86程序集，我为MASM开发了一个简单的程序集应用程序，它调用函数MessageBoxA和ExitProcess，这是源代码：

.386
.model flat, stdcall
option casemap:none

includelib C:\masm\masm32\lib\kernel32.lib
includelib C:\masm\masm32\lib\user32.lib

ExitProcess PROTO :DWORD
MessageBoxA PROTO :DWORD,:DWORD,:DWORD,:DWORD

.data

msg db "Hello There!!", 0
cpt db "My First Programm!!", 0

.code

start:
    push 0   ; MB_OK
    push OFFSET cpt  ; title
    push OFFSET msg  ; msg
    push 0    ; HWND
    call MessageBoxA

    push 0
    call ExitProcess

end start

以上代码在MASM上工作正常，但现在我正在尝试为NASM制作一个等效的代码，这就是我写的：

; test.asm
SECTION .DATA
MsgTitle: db "Message", 10, 0
Message: db "Hello There!", 10, 0

SECTION .TEXT

EXTERN __imp__MessageBoxA@16
EXTERN __imp__ExitProcess@4
GLOBAL _main

_main: ; int main()
    push ebp
    mov ebp, esp
    ;;; Function Main Content
    ; MessageBoxA(NULL, "Hello There!", "Message", MB_OK);
    push 0 ; MB_OK
    push DWORD [MsgTitle]
    push DWORD [Message]
    push 0
    call __imp__MessageBoxA@16
    ; ExitProcess(0)
    push DWORD 0
    call __imp__ExitProcess@4
    ;;;
    mov esp, ebp
    pop ebp
    ;;
    mov eax, 0
    ret

我正在使用Microsoft Incremental Linker链接库User32.lib和kernel32.lib，这是命令行：

nasm -f win32 test.asm -o test.obj
link /SUBSYSTEM:CONSOLE /Entry:main test.obj lib\User32.lib lib\kernel32.lib

问题是在汇编代码并链接obj后，生成的.exe文件不起作用，它显示错误消息“test.exe已停止工作”，有什么问题？

Answer 1

push DWORD [MsgTitle]将位于的前4个字节推送到 MsgTitle。您想要的是推送MsgTitle的地址，其中NASM语法为push DWORD MsgTtitle。因此推论的论点将成为：

push DWORD 0 ; MB_OK
push DWORD MsgTitle
push DWORD Message
push DWORD 0

此外，您的通话不正确。 __imp__MessageBoxA@16本身不是MessageBoxA函数的地址，因此您需要一个级别的间接：

call [__imp__MessageBoxA@16]

调用ExitProcess也是如此。

或者，如果我将__imp__MessageBoxA@16更改为_MessageBoxA@16，我似乎可以使用call _MessageBoxA@16。

在NASM上组装时，装配应用程序不起作用

1 个答案: