Question

我正在通过编写一个简单的“Logged”来尝试Xtend的Active Annotations 调用方法时的跟踪注释。基本上我想在Xtend中写这个：

@Logged
override onCreate()
{
   sampleFuncCall()
}

在Java中得到这样的东西：

@Override void onCreate()
{
   Log.d("TAG", "onCreate started");
   sampleFuncCall();
   Log.d("TAG", "onCreate ended");
}

这是我的第一次尝试：

@Active(LoggedAnnotationProcessor)
@Target(ElementType.METHOD)
annotation Logged {
}

class LoggedAnnotationProcessor extends AbstractMethodProcessor
{
    override doTransform(MutableMethodDeclaration method, extension TransformationContext context) 
    {
        val prefix = "wrapped_"
        method.declaringType.addMethod(prefix + method.simpleName) [ m |
            m.static = method.static
            m.visibility = Visibility.PRIVATE
            m.docComment = method.docComment            
            m.exceptions = method.exceptions
            method.parameters.forEach[ p | m.addParameter(p.simpleName, p.type) ]
            m.body = method.body
            m.primarySourceElement = method
            m.returnType = method.returnType
        ]
        val voidMethod = method.returnType === null || method.returnType.void
        method.body = [ ''' 
                try {
                    android.util.Log.d("TAG", "«method.simpleName» start");
                    «IF (!voidMethod) method.returnType» ret = «ENDIF»
                    «prefix + method.simpleName»(«method.parameters.map[simpleName].join(", ")»);
                    android.util.Log.d("TAG", "«method.simpleName» end");
                    «IF (!voidMethod)»return ret;«ENDIF»
                }
                catch(RuntimeException e) {
                    android.util.Log.d("TAG", "«method.simpleName» ended with exception " 
                        + e.getClass().getSimpleName() + "\n" + e.getMessage());
                    throw e;                
                }
            ''']
    }
}

（注意我找不到修改method.body的方法，并且必须使用“wrapped_”前缀创建一个新的私有方法。我想这对性能有害，所以如果你知道如何修改方法的身体直接，请分享）。

在使用返回void的方法时，我遇到了问题。如果未明确声明方法的返回类型，则会出现以下错误：

无法在推断类型引用之前调用方法'isVoid' 编译阶段。在调用任何方法之前检查isInferred（）。

好的，我可以添加method.returnType.inferred的检查，但是如何处理它 - 似乎在这个阶段我们仍然不知道它是否会无效，但是知道这对于转发方法的返回值。

请告诉我写这样一个注释的正确方法，谢谢！

Answer 1

也许你应该推迟计算。关闭

method.body = [
    val voidMethod = method.returnType === null || method.returnType.void

         ''' 
            try {
                android.util.Log.d("TAG", "«method.simpleName» start");
                «IF (!voidMethod)»«method.returnType» ret = «ENDIF»
                «prefix + method.simpleName»(«method.parameters.map[simpleName].join(", ")»);
                android.util.Log.d("TAG", "«method.simpleName» end");
                «IF (!voidMethod)»return ret;«ENDIF»
            }
            catch(RuntimeException e) {
                android.util.Log.d("TAG", "«method.simpleName» ended with exception " 
                    + e.getClass().getSimpleName() + "\n" + e.getMessage());
                throw e;                
            }
        ''']

如何在Xtend的Active Annotations中获得完整的返回类型转发？

1 个答案: