Question

我正在尝试制作一个将@this转换为“this”的读取器宏。这就是我目前所拥有的：

(defun string-reader (stream char)
   (declare (ignore char))
   (format nil "\"~a\"" (read-line stream t nil t))   
)    
(set-macro-character #\@ #'string-reader )

问题在于这需要我在@this之后添加换行符。我也尝试过（读），但这只是返回尚未设置的变量test。我不能只对@符号后面的字符数进行硬编码，因为我不知道会有多少字符。有什么方法可以解决这个问题吗？

编辑：这是执行此操作以循环遍历read-char和peek-char的唯一方法，直到我到达＃），＃\ space或＃\ Newline？

Answer 1

您可以尝试使用read，然后查看它返回的内容：

(defun string-reader (stream char)
   (declare (ignore char))
   (let ((this (let ((*readtable* (copy-readtable)))
                 (setf (readtable-case *readtable*) :preserve)
                 (read stream t nil t))))
     (etypecase this
       (string this)
       (symbol (symbol-name this)))))

(set-macro-character #\@ #'string-reader)

以上将允许@This和@"This"，但不允许@333。

这个版本只读取一个字符串直到空格：

(defun read-as-string-until-whitespace (stream)
  (with-output-to-string (out-stream)
    (loop for next = (peek-char nil stream t nil t)
          until (member next '(#\space #\newline #\tab))
          do (write-char (read-char stream t nil t) out-stream))))

(defun string-reader (stream char)
   (declare (ignore char))
   (read-as-string-until-whitespace stream))

(set-macro-character #\@ #'string-reader)

示例：

CL-USER 21 > @this
"this"

CL-USER 22 > @42
"42"

CL-USER 23 > @FooBar
"FooBar"

在Lisp阅读器宏中将输入读入字符串

1 个答案: