如何查找字符串中是否存在大写字符？

Question

我需要知道字符串是否至少包含一个字符。我需要找到uppercase字符。

我使用了这段代码：

str testStr;
int flag;
testStr = "abdE2" ;

flag = strScan(testStr , "ABCDEFGHILMNOPQRSTUVZ" ,flag ,strLen(testStr));
info(strFmt("%1",flag) );

但不行！

问题是函数 strScan 不区分大写和小写。

有解决方案吗？

谢谢，

享受！

Answer 1

这是我写的一篇文章，展示了3种不同的比较字符串和区分大小写的方法。只需复制/粘贴/运行。

static void Job86(Args _args)
{
    str a = 'Alex';
    str b = 'aleX';
    int i;
    int n;
    str     c1, c2;


    setPrefix("Compare");
    for (n=1; n<=strLen(b); n++)
    {
        c1 = subStr(a, n, 1);
        c2 = subStr(b, n, 1);

        if (char2num(c1, 1) == char2num(c2, 1))
            info(strFmt("Char2Num()\t%1 == %2", c1, c2));
        else
            info(strFmt("Char2Num()\t%1 != %2", c1, c2));


        if (strCmp(c1, c2) == 0)
            info(strfmt("strCmp()\t%1 == %2", c1, c2));
        else
            info(strFmt("strCmp()\t%1 != %2", c1, c2));

        i = System.String::Compare(c1, c2);

        if (i == 0)
            info(strfmt("System.String::Compare()\t%1 == %2", c1, c2));
        else
            info(strFmt("System.String::Compare()\t%1 != %2", c1, c2));
    }   
}

Answer 2

以下代码测试字符串是否为一个字符或更多字符，然后查找所有大写字符。数字被忽略，因为它们不能是大写的。

static void findCapitalLetters(Args _args)
{
    str testStr = "!#dE2";
    int i;
    int stringLenght = strLen(testStr);
    str character;

    //Find out if a string is at least one character or more
    if (stringLenght >= 1)
    {
        info(strFmt("The string is longer than one character: %1",stringLenght));
    }

    //Find the uppercase character (s)
    for (i=1; i<=stringLenght; i+=1)
    {
        character = subStr(testStr, i, 1);

        if (char2num(testStr, i) != char2num(strLwr(testStr), i))
        {
            info(strFmt("'%1' at position %2 is an uppercase letter.", character, i));
        }
    }  
}

这是输出：

编辑：像Jan B. Kjeldsen所指出的那样，使用char2num(testStr, i) != char2num(strLwr(testStr), i)而非char2num(testStr, i) == char2num(strUpr(testStr), i)来确保它正确评估符号和数字。