Question

我的文件内容与以下内容类似

Boy,Football
Boy,Football
Boy,Football
Boy,Squash
Boy,Tennis
Boy,Football
Girl,Tennis
Girl,Squash
Girl,Tennis
Girl,Tennis
Boy,Football

如何使用'awk'或类似方法将其重新排列为以下内容：

     Football Tennis Squash
Boy  5        1      1
Girl 0        3      1

我甚至不确定这是否可行，但任何帮助都会很棒。

Answer 1

$ cat tst.awk
BEGIN{ FS=","; OFS="\t" }
{
    genders[$1]
    sports[$2]
    count[$1,$2]++
}
END {
    printf ""
    for (sport in sports) {
        printf "%s%s", OFS, sport
    }
    print ""
    for (gender in genders) {
        printf "%s", gender
        for (sport in sports) {
            printf "%s%s", OFS, count[gender,sport]+0
        }
        print ""
    }
}

$ awk -f tst.awk file
        Squash  Tennis  Football
Boy     1       1       5
Girl    1       3       0

通常，当你知道循环的终点时，你会在每个字段后放置OFS或ORS：

for (i=1; i<=n; i++) {
    printf "%s%s", $i, (i<n?OFS:ORS)
}

但是如果你不这样做，那么你将OFS放在第二个和后续的字段之前并在循环之后打印ORS：

for (x in array) {
    printf "%s%s", (++i>1?OFS:""), array[x]
}
print ""

我喜欢：

n = length(array)
for (x in array) {
    printf "%s%s", array[x], (++i<n?OFS:ORS)
}

想要获得循环的结束，但length(array)特定于gawk。

另一种需要考虑的方法：

$ cat tst.awk
BEGIN{ FS=","; OFS="\t" }
{
    for (i=1; i<=NF; i++) {
        if (!seen[i,$i]++) {
            map[i,++num[i]] = $i
        }
    }
    count[$1,$2]++
}
END {
    for (i=0; i<=num[2]; i++) {
        printf "%s%s", map[2,i], (i<num[2]?OFS:ORS)
    }
    for (i=1; i<=num[1]; i++) {
        printf "%s%s", map[1,i], OFS
        for (j=1; j<=num[2]; j++) {
            printf "%s%s", count[map[1,i],map[2,j]]+0, (j<num[2]?OFS:ORS)
        }
    }
}

$ awk -f tst.awk file
        Football        Squash  Tennis
Boy     5       1       1
Girl    0       1       3

最后一个将按照读取的顺序打印行和列。虽然它的工作原理并不那么明显： - ）。

Answer 2

我会正常循环：

awk -F, -v OFS="\t" '
          {names[$1]; sport[$2]; count[$1,$2]++}
          END{printf "%s", OFS;
              for (i in sport) 
                   printf "%s%s", i, OFS;
              print "";
              for (n in names) {
                   printf "%s%s", n, OFS
                   for (s in sport) 
                        printf "%s%s", count[n,s]?count[n,s]:0, OFS; print ""
                   }
               }' file

这会跟踪三个数组：第一列为names[]，第二列为sport[]，count[name,sport]计算每个组合的出现次数。

然后，如果0不存在，则需要循环显示结果并以奇特的方式打印它们并确保打印count[a,b]。

测试

$ awk -F, -v OFS="\t" '{names[$1]; sport[$2]; count[$1,$2]++} END{printf "%s", OFS; for (i in sport) printf "%s%s", i, OFS; print ""; for (n in names) {printf "%s%s", n, OFS; for (s in sport) printf "%s%s", count[n,s]?count[n,s]:0, OFS; print ""}}' a
    Squash  Tennis  Football    
Boy 1   1   5   
Girl    1   3   0

格式有点难看，有一些尾随OFS。

摆脱追踪OFS：

awk -F, -v OFS="\t" '{names[$1]; sport[$2]; count[$1,$2]++} END{printf "%s", OFS; for (i in sport) {cn++; printf "%s%s", i, (cn<length(sport)?OFS:ORS)} for (n in names) {cs=0; printf "%s%s", n, OFS; for (s in sport) {cs++; printf "%s%s", count[n,s]?count[n,s]:0, (cs<length(sport)?OFS:ORS)}}}' a

您可以随时通过管道传输到column -t以获得更好的输出。

重新排列csv文件

2 个答案:

测试