如何在Inno Setup中获取完整的计算机名称

Question

我想知道如何在Inno Setup中获取完整的计算机名称，例如下图中的Win8-CL01.cpx.local。

我已经知道如何使用GetComputerNameString获取计算机名称，但我也想拥有计算机的域名。如何获取此完整计算机名称或此域名？

Answer 1

在Inno Setup中没有内置功能。您可以使用GetComputerNameEx Windows API函数：

[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program

[Code]
#ifdef UNICODE
  #define AW "W"
#else
  #define AW "A"
#endif

const
  ERROR_MORE_DATA = 234;

type
  TComputerNameFormat = (
    ComputerNameNetBIOS,
    ComputerNameDnsHostname,
    ComputerNameDnsDomain,
    ComputerNameDnsFullyQualified,
    ComputerNamePhysicalNetBIOS,
    ComputerNamePhysicalDnsHostname,
    ComputerNamePhysicalDnsDomain,
    ComputerNamePhysicalDnsFullyQualified,
    ComputerNameMax
  );

function GetComputerNameEx(NameType: TComputerNameFormat; lpBuffer: string; var nSize: DWORD): BOOL;
  external 'GetComputerNameEx{#AW}@kernel32.dll stdcall';

function TryGetComputerName(Format: TComputerNameFormat; out Output: string): Boolean;
var
  BufLen: DWORD;
begin
  Result := False;
  BufLen := 0;
  if not Boolean(GetComputerNameEx(Format, '', BufLen)) and (DLLGetLastError = ERROR_MORE_DATA) then
  begin
    SetLength(Output, BufLen);
    Result := GetComputerNameEx(Format, Output, BufLen);
  end;    
end;

procedure InitializeWizard;
var
  Name: string;
begin
  if TryGetComputerName(ComputerNameDnsFullyQualified, Name) then
    MsgBox(Name, mbInformation, MB_OK);
end;

Answer 2

使用内置功能，您可以通过以下方式获取全名：

[Code]
procedure InitializeWizard;
begin
    MsgBox(GetComputerNameString + '.' + GetEnv('UserDnsDomain'), mbInformation, MB_OK);
end;

虽然TLama的解决方案为您提供了更广泛的发展可能性。