Question

鉴于此XML：

<?xml version="1.0" encoding="iso-8859-2" ?>
<r>
    <products start="5" stop="8">
        <p>
            <id> 50 </id>
            <name> Murphy </name>
            <price> 33 </price>
        </p>
        <p>
            <id> 10 </id>
            <name> Margarethe </name>
            <price> 11 </price>
        </p>
    </products>
    <products start="1" stop="4">
        <p>
            <id> 555 </id>
            <name> XXXX</name>
            <price> 333 </price>
        </p>
        <p>
            <id> 10 </id>
            <name> Mexico </name>
            <price> 11 </price>
        </p>
    </products>
    <products start="1" stop="4">
        <p>
            <id> 30 </id>
            <name> HKoney </name>
            <price> 11 </price>
        </p>
        <p>
            <id> 10 </id>
            <name> HMargarethe </name>
            <price> 11 </price>
        </p>
    </products>
</r>

使用此XSL：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0"
encoding="UTF-8" indent="yes"/>

<xsl:template match="products[@start &lt; 2 and @stop &gt; 2]" >
    <xsl:call-template name="test"/>
</xsl:template>

<xsl:template name="test">
     <test><xsl:value-of select="*/name"/></test>
</xsl:template>

<xsl:template match="products"/>

</xsl:stylesheet>

拥有此输出：

<?xml version="1.0" encoding="UTF-8"?>
<test> XXXX</test>
<test> HKoney </test>

问：为什么我没有获得具有指定属性父级的所有<p>，只有第一个属性？预计也会Mexico和HMargarethe。

期望的输出：

<?xml version="1.0" encoding="UTF-8"?>
<test> XXXX</test>
<test> Mexico </test>
<test> HKoney </test>
<test> HMargerethe</test>

注意：我希望在没有for-each循环的情况下让它正常工作。

Answer 1

您必须处理所有p元素，请参阅此处的xsl:for-each：

<xsl:template name="test">
    <test>
        <xsl:for-each select="*">
            <xsl:value-of select="name"/>
        </xsl:for-each>
    </test>
</xsl:template>

Answer 2

您可以尝试直接在apply-templates元素上使用<name>：

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="products[@start &lt; 2 and @stop &gt; 2]" >
        <xsl:apply-templates select="p/name"/>
    </xsl:template>

    <xsl:template match="name">
        <test>
            <xsl:value-of select="."/>
        </test>
    </xsl:template>

    <xsl:template match="products"/>

</xsl:stylesheet>

Answer 3

问：为什么我没有获得具有指定属性父级的所有<p>，只有第一个属性？预计也会Mexico和HMargarethe。

请注意，模板test仅为每个products元素调用一次：

<xsl:template match="products[@start &lt; 2 and @stop &gt; 2]" >
    <xsl:call-template name="test"/>
</xsl:template>

每次调用模板时，都会提取多个name元素以供<xsl:value-of>处理。根据MSDN，有关<xsl:value-of>的select属性：

必需。表达式（XML）将根据当前上下文进行评估。结果将转换为字符串，如通过调用string（）函数。 通过在集合中插入第一个节点的字符串值，将节点集转换为字符串。

规范也讲述了相同的故事，请参阅W3C xslt value-of和xpath function string()

Answer 4

修改了不用于循环的代码

请使用以下代码，它按预期工作

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="/" name ="ParentCopy">
<xsl:param name="LoopCountA">1</xsl:param>
<xsl:variable name = "Count" >
        <xsl:value-of select = "count(r/products)"/>
    </xsl:variable>
    <xsl:choose>
    <xsl:when test ="($LoopCountA  &lt;= $Count) ">
<xsl:choose>
            <xsl:when test ="r/products[$LoopCountA][@start &lt; 2 and @stop &gt; 2]">
                <test>
    <xsl:value-of select = "r/products[$LoopCountA]/p[1]/name"/>
                </test> 
<test>
                    <xsl:value-of select = "r/products[$LoopCountA]/p[2]/name"/>
</test>
            </xsl:when>
</xsl:choose>
    <xsl:call-template name="ParentCopy">
            <xsl:with-param name="LoopCountA">
<xsl:value-of select="$LoopCountA + 1"/>
            </xsl:with-param>
</xsl:call-template>
</xsl:when>
</xsl:choose>
</xsl:template>

</xsl:stylesheet>

让我知道任何其他查询

XSLT：获取具有指定属性的父项的所有子项

4 个答案: