Question

以下代码比较两个Real48的（6字节浮点数）编译和运行，但要么生成非无意义的结果，要么生成AV。

program Project44;

{$APPTYPE CONSOLE}
uses
  System.SysUtils,
  System.Generics.Defaults;

begin
  try
    WriteLn(System.Generics.Defaults.TComparer<Real48>.Default.Compare(100.0,100.0));
    WriteLn('all ok, press space');
  except on E:exception do
    WriteLn(e.Message);
  end;
  ReadLn
end.

它应该输出0，但如果它没有先炸弹，它会输出-92或其他一些不正确的值。

最新的XE8中是否仍存在此错误？
如果是这样，之前有报道，我在https://quality.embarcadero.com上找不到任何内容，但如果有更旧的QC，我想提及它。

最后.... 如何使用REAL48比较两种TComparer<something>类型？

编辑：
这是我解决的问题：

interface
...snip...
[Test]
procedure TestReal48;
...snip...  
    TTest<T> = record
  private
    class var Def: System.Generics.Defaults.IComparer<T>;
    class var F: FastDefaults.TComparison<T>;
  public
    class function Real48Comparison(const Left, Right: T): Integer; static;

implementation

procedure TestDefault.TestReal48;
var
  OldDef: System.Generics.Defaults.IComparer<Real48>;
begin
  OldDef:= TTest<Real48>.Def;
  TTest<Real48>.Def:= System.Generics.Defaults.TComparer<Real48>.Construct(TTest<Real48>.Real48Comparison);
  TTest<Real48>.Test(100.0,100.0);
  TTest<Real48>.Test(100000.0,-10000.0);
  TTest<Real48>.Test(0.0,-10000.0);
  TTest<Real48>.Test(100000.0,0.0);
  TTest<Real48>.Test(0.0,0.0);
  TTest<Real48>.Def:= OldDef;
end;

Answer 1

此缺陷存在于编译器的所有版本中。由于Real48在十多年前被弃用，我预计即使您提交了错误报告，Embarcadero也不会改变行为。当然，您仍然应该提交错误报告，但在等待修复时我不会屏住呼吸！

您必须构建比较器而不是依赖于默认值：

var
  Comparer: IComparer<Real48>;

function Real48Comparison(const Left, Right: Real48): Integer;
begin
  if Left < Right then
    Result := -1
  else if Left > Right then
    Result := 1
  else
    Result := 0;
end;

Comparer := System.Generics.Defaults.TComparer<Real48>.Construct(Real48Comparison);

为什么默认的Real48比较器失败如此之大。好吧，它从这里开始：

class function TComparer<T>.Default: IComparer<T>;
begin
  Result := IComparer<T>(_LookupVtableInfo(giComparer, TypeInfo(T), SizeOf(T)));
end;

发现TypeInfo(Real48)产生nil。似乎没有可用于Real48的类型信息。可能不是一个惊喜。

然后我们到达这里：

function _LookupVtableInfo(intf: TDefaultGenericInterface; info: PTypeInfo; size: Integer): Pointer;
var
  pinfo: PVtableInfo;
begin
  if info <> nil then
  begin
    pinfo := @VtableInfo[intf, info^.Kind];
    Result := pinfo^.Data;
    if ifSelector in pinfo^.Flags then
      Result := TTypeInfoSelector(Result)(info, size);
    if ifVariableSize in pinfo^.Flags then
      Result := MakeInstance(Result, size);
  end
  else
  begin
    case intf of
      giComparer: Result := Comparer_Selector_Binary(info, size);
      giEqualityComparer: Result := EqualityComparer_Selector_Binary(info, size);
    else
      System.Error(reRangeError);
      Result := nil;
    end;
  end;
end;

我们选择else分支并致电Comparer_Selector_Binary。所以我们最终会进行二进制比较。比较实际上是由这个函数执行的：

function Compare_Binary(Inst: PSimpleInstance; const Left, Right): Integer;
begin
  Result := BinaryCompare(@Left, @Right, Inst^.Size);
end;

调用：

function BinaryCompare(const Left, Right: Pointer; Size: Integer): Integer;
var
  pl, pr: PByte;
  len: Integer;
begin
  pl := Left;
  pr := Right;
  len := Size;
  while len > 0 do
  begin
    Result := pl^ - pr^;
    if Result <> 0 then
      Exit;
    Dec(len);
    Inc(pl);
    Inc(pr);
  end;
  Result := 0;
end;

对于真正有价值的类型不会有用。

至于与Real48的ABI相关的运行时错误。似乎Real48参数总是在堆栈上传递。这与在Compare_Binary中使用无类型参数不兼容。

我可以使用generics.defaults比较Real48吗？

1 个答案: