Question

我想清理临时用于收集资源。 file模块只有del_dir / 1，要求目录为空。但是没有函数获取目录中的所有文件（使用绝对路径“）

源代码如下，如何纠正？

 delete_path(X)->
    {ok,List} = file:list_dir_all(X), %% <--- return value has no absolute path here
    lager:debug("_229:~n\t~p",[List]),
    lists:map(fun(X)->
                      lager:debug("_231:~n\t~p",[X]),
                        ok = file:delete(X)
                end,List),
    ok = file:del_dir(X),
    ok.

Answer 1

您可以使用os：cmd通过console命令删除目录，尽管这是一种粗略的方法。对于类似unix的操作系统，它将是：

os:cmd("rm -Rf " ++ DirPath).

如果要使用适当的erlang函数删除非空目录，则必须以递归方式执行此操作。以下here示例说明了如何执行此操作：

-module(directory).
-export([del_dir/1]).

del_dir(Dir) ->
   lists:foreach(fun(D) ->
                    ok = file:del_dir(D)
                 end, del_all_files([Dir], [])).

del_all_files([], EmptyDirs) ->
   EmptyDirs;
del_all_files([Dir | T], EmptyDirs) ->
   {ok, FilesInDir} = file:list_dir(Dir),
   {Files, Dirs} = lists:foldl(fun(F, {Fs, Ds}) ->
                                  Path = Dir ++ "/" ++ F,
                                  case filelib:is_dir(Path) of
                                     true ->
                                          {Fs, [Path | Ds]};
                                     false ->
                                          {[Path | Fs], Ds}
                                  end
                               end, {[],[]}, FilesInDir),
   lists:foreach(fun(F) ->
                         ok = file:delete(F)
                 end, Files),
   del_all_files(T ++ Dirs, [Dir | EmptyDirs]).

Answer 2

现在可以使用file:del_dir/2 API在最新版本的Erlang / OTP（尚未发布）中实现。

可用选项：

递归：在删除目录本身之前，递归删除目录的内容
强制：在访问或删除文件或目录时忽略错误
保留顶部：最顶层的目录未删除

来源：https://github.com/erlang/otp/pull/2565

Answer 3

Erlang中的另一种方法（使用的唯一真正原因是保持平台独立性）：

-spec rm_rf(file:filename()) -> ok.

rm_rf(Dir) ->
    Paths = filelib:wildcard(Dir ++ "/**"),
    {Dirs, Files} = lists:partition(fun filelib:is_dir/1, Paths),
    ok = lists:foreach(fun file:delete/1, Files),
    Sorted = lists:reverse(lists:sort(Dirs)),
    ok = lists:foreach(fun file:del_dir/1, Sorted),
    file:del_dir(Dir).

上面的示例对目标目录相关的当前目录做了一些假设 - 如果这是您使用的问题，建议您明确设置工作目录并完全限定目标路径。< / p>

值得注意的是，类似的方法也可用于递归复制目录。

如何删除非空的整个目录？

3 个答案: