Question

我有一个包含TImage和TButton控件的表单。我注意到响应OnClick事件的速度对于TImage来说似乎有点慢（快速点击！）所以我测量了它。对于100次点击（并尽可能快地点击，保持每个控件的速率尽可能一致），我得到了指标： TButton：平均约105-116ms TImage：平均~220-235ms

我重复了几次，结果相似。为什么TImage处理点击率大约是TButton的一半？处理从WM_LBUTTON_DOWN到OnClick事件的Windows消息队列会更慢吗？如果它们在前一次点击的N ms范围内，可能会吞下Clicks？

TImage的属性似乎没有任何影响这一点的内容。

注意：如果相关，请使用Delphi 7和标准VCL控件。

编辑：这是一些示例代码，演示了我如何计时：

// Define variables (in class definition)
m_dwBtnClicks, m_dwImgClicks: DWORD;
m_dwLastBtnClickTicks, m_dwLastImgClickTicks: DWORD;
m_fTotalBtnClicksTicks, m_fTotalImgClicksTicks: Single;

// Initialise variables (in form's OnCreate event)
m_dwBtnClicks := 0;
m_dwImgClicks := 0;

m_dwLastBtnClickTicks := 0;
m_dwLastImgClickTicks := 0;

m_fTotalImgClicksTicks := 0.0;
m_fTotalImgClicksTicks := 0.0;

// OnClick events
procedure TfrmQwerty.btnClick(Sender: TObject);
var
    dwTime: DWORD;
begin
    // TButton click!
    Inc(m_dwBtnClicks);
    dwTime := GetTickCount();
    if (m_dwLastBtnClickTicks > 0) then
        m_fTotalBtnClicksTicks := (m_fTotalBtnClicksTicks + (dwTime - m_dwLastBtnClickTicks));

    m_dwLastBtnClickTicks := dwTime;
end;

procedure TfrmQwerty.imgClick(Sender: TObject);
var
    dwTime: DWORD;
begin
    // TImage click!
    Inc(m_dwImgClicks);
    dwTime := GetTickCount();
    if (m_dwLastImgClickTicks > 0) then
        m_fTotalImgClicksTicks := (m_fTotalImgClicksTicks + (dwTime - m_dwLastImgClickTicks));

    m_dwLastImgClickTicks := dwTime;
end;

// Some TTimer::OnTimer event to update the results on-screen
procedure TfrmQwerty.OnTextEntryTimer(Sender: TObject);
var
    fTime: Single;
begin
    // Stop the timer
    TextEntryTimer.Enabled := False;

    if (m_dwBtnClicks > 1) then
        begin
        fTime := m_fTotalBtnClicksTicks / m_dwBtnClicks;
        lblButtonClicks.Caption := Format('BtnClicks = %d [Avg = %.3fms]', [
            m_dwBtnClicks, fTime]);
        end;

    if (m_dwImgClicks > 1) then
        begin
        fTime := m_fTotalImgClicksTicks / m_dwImgClicks;
        lblImageClicks.Caption := Format('ImgClicks = %d [Avg = %.3fms]', [
            m_dwImgClicks, fTime]);
        end;

    // Restart the timer
    TextEntryTimer.Enabled := True;
end;

Answer 1

VCL来源是你的朋友。如上所述，这是由Windows在单击足够快速生成它们时发送的双击消息引起的。

让我们看一下当点击足够快以触发双击时会发生什么：

第1步 - 鼠标左键：

procedure TControl.WMLButtonDown(var Message: TWMLButtonDown);
begin
  SendCancelMode(Self);
  inherited;
  if csCaptureMouse in ControlStyle then
    MouseCapture := True;
  if csClickEvents in ControlStyle then  // !! Note here
    Include(FControlState, csClicked);   //    Storing that we've been clicked
  DoMouseDown(Message, mbLeft, []);
end;

第2步 - 鼠标左键上升。

procedure TControl.WMLButtonUp(var Message: TWMLButtonUp);
begin
  inherited;
  if csCaptureMouse in ControlStyle then MouseCapture := False;
  if csClicked in ControlState then      // !! Note here
  begin                                  //    Firing CLICK event primed  
    Exclude(FControlState, csClicked);   //    from the method above
    if ClientRect.Contains(SmallPointToPoint(Message.Pos)) then
      Click;
  end;
  DoMouseUp(Message, mbLeft);
end;

第3步 - 鼠标左键再次关闭。

这一次，它是双击！请注意，这是处理完全不同的消息 - 来自操作系统的双击消息，而不是鼠标按下消息。此处理程序仍会触发MouseDown事件，但当鼠标按钮重新启动时，不会触发控件以触发单击事件。

procedure TControl.WMLButtonDblClk(var Message: TWMLButtonDblClk);
begin
  SendCancelMode(Self);
  inherited;
  if csCaptureMouse in ControlStyle then MouseCapture := True;
  if csClickEvents in ControlStyle then DblClick;
  DoMouseDown(Message, mbLeft, [ssDouble]);
end;

由于Button是一个特殊的TWinControl，它会收到在点击按钮时生成的特殊BN_CLICKED消息，无论它是否是双击。作为一个简单的控件，它可以完成一项简单的工作，因此当您快速单击时（比双击率更快），您可以从按钮看到两倍的点击事件。

procedure TCustomButton.CNCommand(var Message: TWMCommand);
begin
  if Message.NotifyCode = BN_CLICKED then Click;
end;

您还可以注意到，由于TButton会收到这些特殊消息，因此会在csClickEvents中创建而不 ControlStyle选项，所以尽管如此也是TControl，用于TImage（和其他）控件的上述步骤中的处理不适用（即：为Click处理程序中的WMLButtonDown启动）。

正如您所发现的，OnMouseDown或OnMouseUp事件可让您捕获TImage控件中的所有此类事件，无论是将其视为点击还是双击

或者，如果您不关心TImage处理双击，则可以将控件样式设置为：

 Image1.ControlStyle := Image1.ControlStyle - [csDoubleClicks];

此处，TControl.WndProc：

if not (csDoubleClicks in ControlStyle) then
  case Message.Msg of
    WM_LBUTTONDBLCLK, WM_RBUTTONDBLCLK, WM_MBUTTONDBLCLK:
      Dec(Message.Msg, WM_LBUTTONDBLCLK - WM_LBUTTONDOWN);
  end;

您可以看到双击事件转换为简单的鼠标按下事件。

Delphi - 与TButton相比，点击TImage的速度较慢

1 个答案: