如何使用SPSS获取用于获取其他变量频率的唯一案例数？

Question

我有两列，其中包含有关重复测量的人员数据，另一列包含有特征存在或不存在的数据。

数据读起来像这样（列方式）;

• Patient_Code：1 1 2 2 2 3 4 5 5 6 6
• 特征：N Y Y Y N N N Y Y N N

我想要用于获取其他变量中频率的唯一案例数。例如：
 Y - 5（3例/患者）
          N - 6（来自5例/患者）。

如何使用SPSS执行此操作。我有几个这样的特点。

Answer 1

这里的技巧是在每个暴露组中创建患者的唯一标识符。 SORT CASES后跟MATCH FILES实现此目的，CTABLES然后将结果制成表格。

DATA LIST LIST / PatID(f1.0) Exposed(a1).
BEGIN DATA
1 "N"
1 "Y"
2 "Y"
2 "Y"
2 "N"
3 "N"
4 "N"
5 "Y"
5 "Y"
6 "N"
6 "N"
END DATA.

SORT CASES BY Exposed PatID.
MATCH FILES FILE=* /BY Exposed PatID /FIRST=Primary.

CTABLES /VLABELS VARIABLES=Primary DISPLAY=NONE
   /TABLE Exposed[c] by Primary[s][validn 'Count' sum 'Patients']
   /CATEGORIES VARIABLES=Exposed ORDER=D
   /TITLES TITL="Table1: Exposure counts; Patients Exposed".

Answer 2

这可以通过两个AGGREGATE步骤完成：

DATA LIST free / PatID(f1) Exposed(a1).
BEGIN DATA
1 N
1 Y
2 Y
2 Y
2 N
3 N
4 N
5 Y
5 Y
6 N
6 N
END DATA.

DATASET DECLARE count1.
DATASET DECLARE count2.
AGGREGATE /OUTFILE='count1' /BREAK=PatID Exposed /Ncases=N.
dataset activate count1.
AGGREGATE /OUTFILE='count2'/BREAK=Exposed /Ncases=sum(Ncases)/Nuniques=N.

最终结果显示在＆＃39; count2＆＃39;数据集。