Question

我有一个简单的xsl代码来动态显示一些xml。

<xsl:template match="/">
  <xsl:for-each select="NewDataSet/Vehicle">
    <div class="item"> 
        <xsl:value-of select="ManufacturerName" /><br />
        <xsl:value-of select="Model" /><br />
        <xsl:value-of select="Colour" /><br />
        £<xsl:value-of select='format-number(Price, "###,###,##0.")' /> 
    </div>
  </xsl:for-each>
</xsl:template>

我希望能够做的是显示X个随机不同节点集而不是所有节点集。这可能是使用xslt 1.0吗？

感谢。

Answer 1

这是一个示例，显示如何从给定节点集中选择N个随机节点。

您必须有一个方法来生成0到1之间的随机数（不包括1）才能使其工作。在此示例中，EXSLT math：random（）扩展函数用于此目的。如果您使用的是MSXML处理器，请将其替换为扩展功能，如下所示：https://stackoverflow.com/a/6607235/3016153

<强> XML

<list>
    <item id="1">001</item>
    <item id="2">002</item>
    <item id="3">003</item>
    <item id="4">004</item>
    <item id="5">005</item>
    <item id="6">006</item>
    <item id="7">007</item>
    <item id="8">008</item>
    <item id="9">009</item>
    <item id="10">010</item>
    <item id="11">011</item>
    <item id="12">012</item>
</list>

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:math="http://exslt.org/math"
extension-element-prefixes="math">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/list">
    <output>
        <xsl:call-template name="pick-random">
            <xsl:with-param name="node-set" select="item"/>
            <xsl:with-param name="quota" select="5"/>
        </xsl:call-template>
    </output>
</xsl:template>

<xsl:template name="pick-random">
    <xsl:param name="node-set"/>
    <xsl:param name="quota"/>
    <xsl:param name="selected" select="dummy-node"/>    
    <xsl:choose>
        <xsl:when test="count($selected) &lt; $quota and $node-set">
            <xsl:variable name="set-size" select="count($node-set)"/>    
            <xsl:variable name="rand" select="floor(math:random() * $set-size) + 1"/>       
            <!-- recursive call -->
            <xsl:call-template name="pick-random">
                <xsl:with-param name="node-set" select="$node-set[not(position()=$rand)]"/>
                <xsl:with-param name="quota" select="$quota"/>
                <xsl:with-param name="selected" select="$selected | $node-set[$rand]"/>         
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy-of select="$selected"/>
        </xsl:otherwise>
     </xsl:choose>
</xsl:template>

</xsl:stylesheet>

结果（运行示例）

<?xml version="1.0" encoding="UTF-8"?>
<output>
   <item id="1">001</item>
   <item id="3">003</item>
   <item id="8">008</item>
   <item id="10">010</item>
   <item id="12">012</item>
</output>

注意：此方法会保留所选项目的内部顺序。

使用XSLT 1.0显示X个不同的随机节点集

1 个答案: