Question

data a1

a b c
2 3 4
1 2 3

data a2

a b  d
0 .3 1
0 .2 0


proc sql;
create table a3 as
select a.*, a.a * b.a + a.b * b.b as Value
from a1 a, a2 b;

a1和a2中有许多常见列（具有不同值的数字列）。我想将Value计算为这些常用列的“sumproduct”。

我尽量避免使用a.common1 * b.common1 + a.common2 * b.common2 + ...

之类的内容

Answer 1

这需要相当多的代码来实现这种动态。我会这样打破它：

获取每个数据集中存在的变量列表
合并列表以获取常见变量列表
在数据步骤中将其提供给某些数组逻辑

稍后会发布一些代码，但希望这足以给你一些想法。

Answer 2

据我所知，需要几步预处理......

加载您的数据：

data a1 ;
input a b c ;
cards ;
2 3 4
1 2 3
;run ;

data a2 ;
input a b d ;
cards ;
0 0.3 1 
0 0.2 0
;run ;

拉出A1和A2数据集中的所有变量名称（如果需要，更新您的libname）：

proc sql ;
create table data1 as
select libname, memname, name, label
    from sashelp.vcolumn
    where libname= 'WORK' and memname in ('A1','A2')
    order by name
;quit ;

仅保留两个数据集共有的变量：

data data2 ;
  set data1 ;
  by name ;
  if last.name and not first.name ;
run ;

将公共变量的列表和计数都放入宏变量中：

proc sql ;
select name
  into :commvarnames separated by ' ' 
  from data2
;
select count(name)
  into :commoncount
  from data2
;quit ;

读入源数据集 - 加载第一个数据集，将它们传输到临时数组（因此它们不会覆盖变量值），然后加载第二个数据集并在do循环中进行计算：

data output ;
  set a1(keep=&commvarnames) ;  
  array one(&commoncount) _temporary_ ;
  array two(&commoncount) &commvarnames ;

  * Load A1 to temporary array ;
  do i=1 to &commoncount ;
    one(i)=two(i) ;
  end ;

  * Load A2 to variables ;
  set a2(keep=&commvarnames) ;  

  do i=1 to &commoncount ;
    product=sum(product,one(i)*two(i)) ;
  end ;
run ;

两个数据集中的公共变量的乘积

2 个答案: