Question

我有以下多名称空间XML文件：objects.xml

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="objects.xsl"?>
<objects
    xmlns:objA="http://www.mywebsite.com/objectA"
    xmlns:objB="http://www.mywebsite.com/objectB"
>
    <objA:objectA>
        <objA:attrA1>Instance 1 Value 1</objA:attrA1>
        <objA:attrA2>Instance 1 Value 2</objA:attrA2>
    </objA:objectA>
    <objB:objectB>
        <objB:attrB1>Instance 2 Value 1</objB:attrB1>
        <objB:attrB2>Instance 2 Value 2</objB:attrB2>
    </objB:objectB>
    <objA:objectA>
        <objA:attrA1>Instance 3 Value 1</objA:attrA1>
        <objA:attrA2>Instance 3 Value 2</objA:attrA2>
    </objA:objectA>
    <objB:objectB>
        <objB:attrB1>Instance 4 Value 1</objB:attrB1>
        <objB:attrB2>Instance 4 Value 2</objB:attrB2>
    </objB:objectB>
</objects>

以及以下样式表XLST文件：objects.xsl

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:objA="http://www.mywebsite.com/objectA"
    xmlns:objB="http://www.mywebsite.com/objectB"
>

<xsl:template match="/">
  <html>
  <body>

<xsl:for-each select="/objects/objA:objectA">
    (<xsl:value-of select="objA:attrA1"/> |
    <xsl:value-of select="objA:attrA2"/>)<br />
</xsl:for-each>

<xsl:for-each select="/objects/objB:objectB">
    (<xsl:value-of select="objB:attrB1"/> |
    <xsl:value-of select="objB:attrB2"/>)<br />
</xsl:for-each>

  </body>
  </html>
</xsl:template>

</xsl:stylesheet>

但结果并不完全是我想要的，因为上面的文件我得到了：

(Instance 1 Value 1 | Instance 1 Value 2)
(Instance 3 Value 1 | Instance 3 Value 2)
(Instance 2 Value 1 | Instance 2 Value 2)
(Instance 4 Value 1 | Instance 4 Value 2)

与XML文件的顺序不同。我需要与objects.xml相同的订单：{1,2,3,4}

我知道问题是应用于不同点的for-each语句，但我给出了上面的代码来显示我想要的近似值。

我尝试仅使用一个for-each语句使用通配符作为命名空间，但似乎不允许使用通配符作为名称空间。

有什么想法吗？

Answer 1

试试这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <html>
            <body>
                <xsl:apply-templates select="/objects/*"/>
            </body>
        </html>
    </xsl:template>
    <xsl:template match="*">
        <xsl:value-of select="concat('(', *[1],' | ', *[2],')')"/>
        <br/>
    </xsl:template>
</xsl:stylesheet>

使用XSL显示XML节点但在XML上保持顺序 - 使用多个名称空间

1 个答案: