Question

我需要在一个过程中执行FOR EACH循环，但我需要动态传递表名。

这是声明

CREATE OR REPLACE PROCEDURE MIGRATE_PRIMITIVES_PROPS
(
    FromTable IN VARCHAR2, 
    ToTable IN VARCHAR2
)

当我尝试这样做时 FOR EachRow IN (SELECT * FROM FromTable)它表示该表无效

进入该过程的表是动态的，列一直被添加和删除，所以我不能拼出列并用光标填充它们。

Answer 1

您必须使用动态SQL来查询在编译时您不知道其名称的表。您可以使用动态游标执行此操作：

as
    l_cursor sys_refcursor;
begin
    open l_cursor for 'select * from ' || fromtable;
    loop
      fetch l_cursor into ...

...但是它会因为你无法定义要提取到based on a weak ref cursor的记录类型而崩溃;并且您不知道您实际感兴趣的列名称或类型 - 您使用的是select *并且具有要排除的特定名称，而不包括。你提到了一个可以工作并获取列名的内部循环，但是该游标变量中还有no way to refer to a field。

所以你必须更努力地工作并使用the dbms_sql package而不是本机动态SQL。

这是一个基本版本：

create or replace procedure migrate_primitives_props
(
    fromtable in varchar2, 
    totable in varchar2
)
as
    l_cursor pls_integer;
    l_desc_tab dbms_sql.desc_tab;
    l_columns pls_integer;
    l_value varchar2(4000);
    l_status pls_integer;
begin
    l_cursor := dbms_sql.open_cursor;

    -- parse the query using the parameter table name
    dbms_sql.parse(l_cursor, 'select * from ' || fromtable, dbms_sql.native);
    dbms_sql.describe_columns(l_cursor, l_columns, l_desc_tab);

    -- define all of the columns
    for i in 1..l_columns loop
        dbms_sql.define_column(l_cursor, i, l_value, 4000);
    end loop;

    -- execute the cursor query
    l_status := dbms_sql.execute(l_cursor);

    -- loop over the rows in the result set
    while (dbms_sql.fetch_rows(l_cursor) > 0) loop
        -- loop over the columns in each row
        for i in 1..l_columns loop
            -- skip the columns you aren't interested in
            if l_desc_tab(i).col_name in ('COL_NAME', 'LIB_NAME', 'PARTNAME',
                'PRIMITIVE', 'PART_ROW')
            then
                continue;
            end if;

            -- get the column value for this row
            dbms_sql.column_value(l_cursor, i, l_value);
            -- insert the key-value pair for this row
            execute immediate 'insert into ' || totable
                || '(key, value) values (:key, :value)'
                using l_desc_tab(i).col_name, l_value;
        end loop;
    end loop;
end;
/

我假设你知道ToTable中的列名，但仍然使用动态插入语句，因为该表名是未知的。（这看起来很奇怪，但是......）

创建并填充样本表，然后使用其名称调用该过程：

create table source_table (col_name varchar2(30), lib_name varchar2(30),
  partname varchar2(30), primitive number, part_row number,
  col1 varchar2(10), col2 number, col3 date);
create table target_table (key varchar2(30), value varchar2(30));

insert into source_table (col_name, lib_name, partname, primitive, part_row,
  col1, col2, col3)
values ('A', 'B', 'C', 0, 1, 'Test', 42, sysdate);

exec migrate_primitives_props('source_table', 'target_table');

最终得到的目标表包含：

select * from target_table;

KEY                            VALUE                        
------------------------------ ------------------------------
COL1                           Test                          
COL2                           42                            
COL3                           2015-05-22 15:29:31

这是基本的，因为它没有清理输入（查找the dbms_assert package），并且没有对不同的数据类型进行任何特殊处理。在我的例子中，我的源表有一个日期列;目标表根据调用会话的NLS_DATE_FORMAT设置获取该日期值的字符串表示，这是不理想的。有一种简单但有点hacky的方式来获得一致的日期格式，以及更好但更复杂的方式;但是你可能没有日期值，所以这可能已经足够好了。

每个传递tablename到过程的ORACLE PL / SQL

1 个答案: