在Excel中仅显示月份列表中重复的名称一次（2010）

Question

我在表单1上有离开表，其中包含以下标题

A列=月份; B列=姓名; C栏= ......

现在在表2中，我在Cell H59中有一个月数据验证列表。

问题：当我从数据验证列表中选择特定月份时，离开表格（B列）中的所有名称都应显示，而不会重复任何名称。

例如：

 January                 Alpha      
 January                 Alpha
 January                 Bravo
 February                Charlie
 February                Alpha
 March                   Bravo
 April                   Charlie
 May                     Bravo
 May                     Bravo
 May                     Charlie
 May                     Alpha
 May                     Alpha

当我选择月份“MAY”时，我希望单元格显示如下：

Bravo
Charlie
Alpha

不

Bravo
Bravo
Charlie
Alpha
Alpha

当前 ARRAY 公式（显示与第二个选项类似）

{=IFERROR(INDEX(TeamLeaves[Name],SMALL(IF((TeamLeaves[Month]=Dashboard!$H$59),ROW(TeamLeaves[Month])-ROW(Leaves!$A$3)+1),ROWS(Leaves!$A$3:Leaves!$A3))),"")}

请帮忙！ （没有VBA）

最佳！

Answer 1

这是一种使用 Helper列的方法，可以根据您的需要进行调整。我们将您的数据放在 A 和 B 列中，并将验证列表单元格放在 E1 中。

在 C1 中输入：

=IF(A1<>$E$1,"",ROW())

并在 C2 中输入：

=IF(A2<>$E$1,"",IF(SUMPRODUCT(($A$1:A1=$E$1)*($B$1:B1=B2))>0,"",1+MAX($C$1:C1)))

并复制下来。列 C 标记要检索的项目。

在 E2 中输入：

=IFERROR(INDEX($B$1:$B$20,MATCH(ROWS($1:1),$C$1:$C$20,0)),"")

并复制下来：

此方法避免了数组公式。