Question

我使用CliBuilder来解析一些命名参数（h，t，c，n，s）：

hl7-benchmark -t xxx -c yyy -n zzz -s aaa:bbb final_value_without_name

调用命令行如下所示：hl7-benchmark -t xxx -c yyy -n zzz -s aaa：bbb

我需要在最后添加一个可选属性，但我不希望它被命名，如：

{{1}}

CliBuilder有可能吗？我找不到任何这方面的例子。

谢谢！

Answer 1

您可以简单地将其作为＆＃34; 参数＆＃34;命令行的一部分：

def test(args) {
    def cli = new CliBuilder(usage: 'hl7-benchmark -[t] type -[c] concurrency -[n] messages -[s] ip:port')

    cli.with {
        h longOpt: 'help', 'Show usage information'
        t longOpt: 'type',        args: 1, argName: 'type',        'mllp|soap'
        c longOpt: 'concurrency', args: 1, argName: 'concurrency', 'number of processes sending messages'
        n longOpt: 'messages',    args: 1, argName: 'messages',    'number of messages to be send by each process'
        s longOpt: 'ip:port',     args: 2, argName: 'ip:port',     'server IP address:server port',                  valueSeparator: ':'
    }

    def options = cli.parse(args)
    def otherArguments = options.arguments()

    println options.t
    println options.c
    println options.n      
    println options.ss  // http://www.kellyrob99.com/blog/2009/10/04/groovy-clibuilder-with-multiple-arguments/#hide
    println otherArguments
}

test(['-t', 'xxx', '-c', 'yyy', '-n', 'zzz', '-s', 'aaa:bbb', 'final_value_without_name'])

以上给出：

xxx
yyy
zzz
[aaa, bbb]
[final_value_without_name]

如果您希望在放置选项之前正确解析参数，则可以将stopAtNonOption设置为false，例如CliBuilder argument without dash

如何使用Groovy CliBuilder解析非命名的arg值？

1 个答案: