Question

我的XML中有一个字符串，它将返回一个分隔的值列表。类似于这个字符串的东西：

<Item>Code^ReturnCode|Description^ReturnDescription|System^ReturnSystem</Item>

我正在寻找的是

的输出

<Item>
  <Code>ReturnCode</Code> 
  <Description>ReturnDescription</Description> 
  <System>ReturnSystem</System>
<Item>

元素名称和值完全是动态的。我知道我已接近这个想法，但这是我的第一个XSLT。以下是我到目前为止的情况：

<xsl:template match="/Container/Information" >
   <xsl:call-template name="splitReturn">
        <xsl:with-param name="String" select="text()"/>
        <xsl:with-param name="Separator" select="'|'"/>
   </xsl:call-template>
</xsl:template>

<xsl:template name="splitReturn">
    <xsl:param name="String"/>
    <xsl:param name="Separator"/>
    <xsl:element name="{substring-before($String,$Separator)}">
        <xsl:value-of select="substring-after($String,$Separator)" />
    </xsl:element>  
</xsl:template>

我想我只是错过了如何嵌套我正在申请的模板。

Answer 1

您必须递归模板。尝试：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/Item">
    <xsl:copy>
        <xsl:call-template name="splitReturn"/>
    </xsl:copy>
</xsl:template>     

<xsl:template name="splitReturn">
    <xsl:param name="string" select="."/>
    <xsl:variable name="token" select="substring-before(concat($string, '|'), '|')" />    
    <xsl:if test="$token">
        <xsl:element name="{substring-before($token, '^')}">
            <xsl:value-of select="substring-after($token, '^')" />
        </xsl:element>  
    </xsl:if>
    <xsl:if test="contains($string, '|')">
        <!-- recursive call -->
        <xsl:call-template name="splitReturn">
            <xsl:with-param name="string" select="substring-after($string, '|')"/>
        </xsl:call-template>
    </xsl:if>
</xsl:template>

</xsl:stylesheet>

当这应用于您的输入示例时：

<Item>Code^ReturnCode|Description^ReturnDescription|System^ReturnSystem</Item>

结果将是：

<?xml version="1.0" encoding="utf-8"?>
<Item>
   <Code>ReturnCode</Code>
   <Description>ReturnDescription</Description>
   <System>ReturnSystem</System>
</Item>

请注意，仅当提供的名称是有效的XML元素名称时，这才有效。

将字符串拆分为动态元素名称和值

1 个答案: