Question

有时检查某些事情是否构建不好，例如：

// Next line should fail to compile: can't convert const iterator to iterator.
my_new_container_type::iterator it = my_new_container_type::const_iterator();

是否有可能将这些类型的东西纳入CMake / CTest？我在CMakeLists.txt：

中寻找类似的内容

add_build_failure_executable(
    test_iterator_conversion_build_failure
    iterator_conversion_build_failure.cpp)
add_build_failure_test(
    test_iterator_conversion_build_failure
    test_iterator_conversion_build_failure)

（当然，据我所知，这些特定的CMake指令并不存在。）

Answer 1

如您所述，您可以或多或少地执行此操作。您可以添加一个无法编译的目标，然后添加一个调用cmake --build的测试来尝试构建目标。剩下的就是将测试属性WILL_FAIL设置为true。

所以，假设您在名为＆＃34; will_fail.cpp＆＃34;的文件中进行了测试。其中包含：

#if defined TEST1
non-compiling code for test 1
#elif defined TEST2
non-compiling code for test 2
#endif

然后您可以在CMakeLists.txt中使用以下内容：

cmake_minimum_required(VERSION 3.0)
project(Example)

include(CTest)

# Add a couple of failing-to-compile targets
add_executable(will_fail will_fail.cpp)
add_executable(will_fail_again will_fail.cpp)
# Avoid building these targets normally
set_target_properties(will_fail will_fail_again PROPERTIES
                      EXCLUDE_FROM_ALL TRUE
                      EXCLUDE_FROM_DEFAULT_BUILD TRUE)
# Provide a PP definition to target the appropriate part of
# "will_fail.cpp", or provide separate files per test.
target_compile_definitions(will_fail PRIVATE TEST1)
target_compile_definitions(will_fail_again PRIVATE TEST2)

# Add the tests.  These invoke "cmake --build ..." which is a
# cross-platform way of building the given target.
add_test(NAME Test1
         COMMAND ${CMAKE_COMMAND} --build . --target will_fail --config $<CONFIGURATION>
         WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
add_test(NAME Test2
         COMMAND ${CMAKE_COMMAND} --build . --target will_fail_again --config $<CONFIGURATION>
         WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
# Expect these tests to fail (i.e. cmake --build should return
# a non-zero value)
set_tests_properties(Test1 Test2 PROPERTIES WILL_FAIL TRUE)

如果您有很多要编写的内容，显然可以将所有这些内容包装到函数或宏中。

Answer 2

@ Fraser的回答是一个很好的方法，特别是WILL_FAIL属性是一个很好的建议。但是，有一个替代方案可以使主要项目的失败目标成为一部分。问题中的用例几乎是ctest --build-and-test模式的用途。您可以将它放在自己独立的迷你项目中，然后将其作为测试的一部分构建，而不是将主要构建的预期失败目标作为部分。这可能在主项目中看起来如下所示：

add_test(NAME iter_conversion
    COMMAND ${CMAKE_CTEST_COMMAND}
            --build-and-test
                ${CMAKE_CURRENT_LIST_DIR}/test_iter
                ${CMAKE_CURRENT_BINARY_DIR}/test_iter
            --build-generator ${CMAKE_GENERATOR}
            --test-command ${CMAKE_CTEST_COMMAND}
)
set_tests_properties(iter_conversion PROPERTIES WILL_FAIL TRUE)

这样做的好处是它将成为项目测试结果的一部分，因此更有可能作为正常测试过程的一部分定期执行。在上面的示例中，test_iter目录本质上是它自己的独立项目。如果您需要从主构建中向其传递信息，可以通过添加--build-options来定义缓存变量以传递给它的CMake运行。检查latest docs，了解此区域最近更正/澄清的帮助。

在CMake中预期的构建失败测试

2 个答案: