Question

我有这个XML代码：

    <getDocument xmlns:ns="http://ecm.thehartford.com/ecm_cmd_doc/2009-06">
    <ns:ecm_cmd_doc>
    <ns:ecm_application_name>gbcledm</ns:ecm_application_name>
    <ns:ecm_operation>
        <mode>synchronous</mode>
        <name>view</name>
    </ns:ecm_operation>
    <ns:doc_selection>
        <ns:doc_object>
            <dctm_object_type>ecm_gbd_bill_corr_doc</dctm_object_type>
            <ns:doc_attr>
                <attr_value>6762884</attr_value>
                <attr_name>bill_number</attr_name>
            </ns:doc_attr>
        </ns:doc_object>
    </ns:doc_selection>
    </ns:ecm_cmd_doc>
    </getDocument>

我想转换成：

  <getDocument xmlns:ns="http://ecm.thehartford.com/ecm_cmd_doc/2009-06">
  <ns:ecm_application_name>gbcledm</ns:ecm_application_name>
  <ns:ecm_cmd_doc>
    <ns:ecm_operation mode="synchronous" name="view"/>
    <ns:doc_selection>
        <ns:doc_object dctm_object_type="ecm_gbd_bill_corr_doc">
            <ns:doc_attr attr_value="6762884" attr_name="bill_number"/>
        </ns:doc_object>
    </ns:doc_selection>
  </ns:ecm_cmd_doc>
  </getDocument>

也就是说，所有元素都将转换为属性，但ns:ecm_application_name将保持不变。我试过这个xslt代码：

     <xsl:stylesheet version="1.0" xmlns:ns="http://ecm.thehartford.com/ecm_cmd_doc/2009-06" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>
     <xsl:strip-space elements="*"/>
     <xsl:template match="*">
     <xsl:choose>
     <xsl:when test="ns:ecm_application_name">
     <xsl:copy-of select="ns:ecm_application_name"/>
     </xsl:when>
     </xsl:choose>
     <xsl:copy>
     <xsl:for-each select="@*|*[not(* or @*)]">
     <xsl:attribute name="{name(.)}">
     <xsl:value-of select="."/>
     </xsl:attribute>
     </xsl:for-each>
     <xsl:apply-templates select="*[* or @*]|text()"/>
     </xsl:copy>
     </xsl:template>
     </xsl:stylesheet>

非常感谢您的帮助。

Answer 1

也许这对你有用。它接受除ns:ecm_application_name之外的所有叶节点（没有自己子元素的元素）并将它们转换为其父节点的属性。

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns="http://ecm.thehartford.com/ecm_cmd_doc/2009-06">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[not(*)]">
    <xsl:attribute name="{local-name()}">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

<xsl:template match="ns:ecm_application_name" priority="1">
    <xsl:copy-of select="."/>
</xsl:template>

</xsl:stylesheet>

结果（与您发布的结果不同）

<getDocument xmlns:ns="http://ecm.thehartford.com/ecm_cmd_doc/2009-06">
   <ns:ecm_cmd_doc>
      <ns:ecm_application_name>gbcledm</ns:ecm_application_name>
      <ns:ecm_operation mode="synchronous" name="view"/>
      <ns:doc_selection>
         <ns:doc_object dctm_object_type="ecm_gbd_bill_corr_doc">
            <ns:doc_attr attr_value="6762884" attr_name="bill_number"/>
         </ns:doc_object>
      </ns:doc_selection>
   </ns:ecm_cmd_doc>
</getDocument>

-

AFAICT，以下变体：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:ns="http://ecm.thehartford.com/ecm_cmd_doc/2009-06">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="getDocument">
    <xsl:copy>
        <xsl:copy-of select="ns:ecm_cmd_doc/ns:ecm_application_name"/>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="*[not(*)]">
    <xsl:attribute name="{local-name()}">
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

<xsl:template match="ns:ecm_application_name" priority="1"/>

</xsl:stylesheet>

将返回预期结果，无论是设计还是巧合。

XSLT将所有元素转换为属性，保留一个节点

1 个答案: