Question

鉴于此XML ......

<?xml version="1.0" encoding="UTF-8"?>
<root>
    <item>
        <this>
<that>one</that>
        </this>
    </item>
    <item>
        <this>
<that>two</that>
        </this>
    </item>
    <item>
        <this>
<that>three</that>
        </this>
    </item>
</root>

我想将这些项目的副本制作成新的格式，看起来像......

<new>
  <parm x="&gt;that&lt;one&gt;/that&lt;"/>
  <parm x="&gt;that&lt;two&gt;/that&lt;"/>
  <parm x="&gt;that&lt;three&gt;/that&lt;"/>
</new>

样式表......

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="feedKey"/>

    <xsl:template match="/">
        <new>
            <xsl:apply-templates select="//item"/>
        </new>
    </xsl:template>

    <xsl:template match="item">
        <xsl:element name="param">
            <xsl:attribute name="x"><xsl:copy-of select="node()"/></xsl:attribute>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

... ...产生

<?xml version="1.0" encoding="UTF-8"?>
<new>
   <param x="&#xA;        &#xA;one&#xA;        &#xA;    "/>
   <param x="&#xA;        &#xA;two&#xA;        &#xA;    "/>
   <param x="&#xA;        &#xA;three&#xA;        &#xA;    "/>
</new>

对工作表进行简单更改以删除属性...

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:param name="feedKey"/>

    <xsl:template match="/">
        <new>
            <xsl:apply-templates select="//item"/>
        </new>
    </xsl:template>

    <xsl:template match="item">
        <xsl:element name="param">
            <xsl:copy-of select="node()"/>
        </xsl:element>
    </xsl:template>

</xsl:stylesheet>

... ...产生

<?xml version="1.0" encoding="UTF-8"?>
<new>
   <param>
        <this>
         <that>one</that>
        </this>
    </param>
   <param>
        <this>
         <that>two</that>
        </this>
    </param>
   <param>
        <this>
         <that>three</that>
        </this>
    </param>
</new>

如何将“this”转换为属性“x”，并删除空格并编码标签？

Answer 1

此转化：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
  <new>
    <xsl:apply-templates select="*/*/this/*"/>
  </new>
 </xsl:template>

 <xsl:template match="*">
  <xsl:variable name="vStr">
    <xsl:text>&lt;</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:text>&gt;</xsl:text>

    <xsl:apply-templates/>

    <xsl:text>&lt;/</xsl:text>
    <xsl:value-of select="name()"/>
    <xsl:text>&gt;</xsl:text>
  </xsl:variable>

  <parm x="{$vStr}"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档：

<root>
    <item>
        <this>
            <that>one</that>
        </this>
    </item>
    <item>
        <this>
            <that>two</that>
        </this>
    </item>
    <item>
        <this>
            <that>three</that>
        </this>
    </item>
</root>

产生所需的结果：

<new>
    <parm x="&lt;that&gt;one&lt;/that&gt;"/>
    <parm x="&lt;that&gt;two&lt;/that&gt;"/>
    <parm x="&lt;that&gt;three&lt;/that&gt;"/>
</new>

Answer 2

据我所知，如果我理解你的问题;在XSLT中没有办法做到这一点。我的假设是W3C考虑将转义的XML存储为反模式。我的方法是定义一个命名模板：

<xsl:template name='recursive_escape'>
<xsl:text>;&lt;</xsl:text>
<xsl:value-of select='local-name()'/>
<xsl:for-each select='child::attribute()'>
<xsl:value-of select='local-name()'/>
<xsl:text>='</xsl:text><xsl:value-of select='.'/><xsl:text>'</xsl:text>
</xsl:for-each>
<xsl:text>/;&gt;</xsl:text>....

等等。我希望你能解读我在这里尝试做的事情：手动构造一个带有上下文节点名称的开始标记以及每个属性的名称和值，然后迭代上下文节点的每个子节点并调用相同的模板再次;等等。我没有把原来的实现交到这里，所以毫无疑问我的例子有些不对劲;这只是一个指南。

如果有人知道我想听的更好的方式;它可能在XSLT 2.0中尚未正式化，IIRC。对于健壮性和MSXML支持，它必须是XSLT 1.0。

如何使用XSLT将节点集复制到结果属性而不使用空格和标签进行编码？

2 个答案: