Question

我想知道是否有可能将数字放在一个范围内并将它们打印成自己的元素。

假设我输入了很多带有数字的元素，其中一些包含数字范围：

<root>
<ele>
    <no>1</no>
</ele>
<ele>
    <no>3</no>
</ele>
<ele>
    <no>4-11</no>
</ele>
<ele>
    <no>12</no>
</ele>

我希望得到这个（缩短，最多11个，就像在输入中一样）：

<root>
<ele>
    <no>1</no>
</ele>
<ele>
    <no>3</no>
</ele>
<ele>
    <no>4</no>
</ele>
<ele>
    <no>5</no>
</ele>
<ele>
    <no>6</no>
</ele>

到目前为止，我已经提出了这个XSLT：

 <xsl:output indent="yes"/>
<xsl:template match="/">
    <xsl:for-each select="//no">
        <no>
            <xsl:if test="not(contains(.,'-'))"><xsl:value-of select="."/></xsl:if>
            <xsl:if test="contains(.,'-')">
                <xsl:variable name="beforehiven">
                    <xsl:value-of select="substring-before(.,'-')"/>
                </xsl:variable>
                <xsl:variable name="afterhiven">
                    <xsl:value-of select="substring-after(.,'-')"/>
                </xsl:variable>
                <xsl:variable name="diff">
                    <xsl:value-of select="$afterhiven - $beforehiven"/>
                </xsl:variable>
                <xsl:value-of select="$diff"/>
            </xsl:if>
        </no>
    </xsl:for-each>
</xsl:template>

首先，我点击没有hiven的那些并输出它们。我知道4到11之间是6个数字，所以我必须创建新的<ele>和<no>元素并给它们值7-1，为下一个创建一个新的变量6-1等等。

XSLT可以实现吗？如果有，怎么样？

谢谢你的时间！

编辑：我正在使用xslt版本2.0

完整的输出应该是：

<root>
<ele>
    <no>1</no>
</ele>
<ele>
    <no>3</no>
</ele>
<ele>
    <no>4</no>
</ele>
<ele>
    <no>5</no>
</ele>
<ele>
    <no>6</no>
</ele>
<ele>
    <no>7</no>
</ele>
<ele>
    <no>8</no>
</ele>
<ele>
    <no>9</no>
</ele>
<ele>
    <no>10</no>
</ele>
<ele>
    <no>11</no>
</ele>
<ele>
    <no>12</no>
</ele>

Answer 1

使用XSLT 2.0，这应该非常简单：

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema"
exclude-result-prefixes="xs">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="ele[contains(no, '-')]">
    <xsl:variable name="from" select="substring-before(no, '-')" />
    <xsl:variable name="to" select="substring-after(no, '-')"/>
    <xsl:for-each select="xs:integer($from) to xs:integer($to)">
        <ele>
            <no>
                <xsl:value-of select="."/>
            </no>
        </ele>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

获取

1 个答案: